Q 语言 - 函数式查询

函数式（动态）查询允许将列名指定为符号，用于典型的 q-sql select/exec/delete 列。当我们想要动态指定列名时，它非常方便。

函数式形式为：

?[t;c;b;a]    / for select
![t;c;b;a]    / for update

其中

t 是一个表格；
a 是一个聚合字典；
b 是 by-短语；以及
c 是一个约束列表。

注意：

a、b 和 c 中的所有 q 实体都必须按名称引用，即包含实体名称的符号。
select 和 update 的语法形式由 q 解释器解析为等效的函数式形式，因此两种形式之间没有性能差异。

函数式 select

以下代码块显示了如何使用 函数式 select：

q)t:([]n:`ibm`msft`samsung`apple;p:40 38 45 54)

q)t

    n       p
-------------------
   ibm     40
   msft    38
 samsung   45
  apple    54

q)select m:max p,s:sum p by name:n from t where p>36, n in `ibm`msft`apple

  name |   m   s
------ | ---------
 apple |  54  54
 ibm   |  40  40
 msft  |  38  38

示例 1

让我们从最简单的案例开始，“select from t” 的函数式版本将如下所示：

q)?[t;();0b;()]     / select from t

    n      p
-----------------
   ibm    40
   msft   38
 samsung  45
  apple   54

示例 2

在下面的示例中，我们使用 enlist 函数创建单例以确保适当的实体是列表。

q)wherecon: enlist (>;`p;40)

q)?[`t;wherecon;0b;()] / select from t where p > 40

    n      p
----------------
 samsung  45
  apple   54

示例 3

q)groupby: enlist[`p] ! enlist `p

q)selcols: enlist [`n]!enlist `n

q)?[ `t;(); groupby;selcols]        / select n by p from t

   p  |    n
----- | -------
  38  |  msft
  40  |  ibm
  45  | samsung
  54  | apple

函数式 Exec

exec 的函数式形式是 select 的简化形式。

q)?[t;();();`n]                / exec n from t (functional form of exec)
`ibm`msft`samsung`apple

q)?[t;();`n;`p]                / exec p by n from t (functional exec)

apple   | 54
ibm     | 40
msft    | 38
samsung | 45

函数式 Update

update 的函数式形式与 select 完全类似。在下面的示例中，使用 enlist 是为了创建单例，以确保输入实体是列表。

q)c:enlist (>;`p;0)

q)b: (enlist `n)!enlist `n

q)a: (enlist `p) ! enlist (max;`p)

q)![t;c;b;a]

   n      p
-------------
  ibm    40
  msft   38
 samsung 45
 apple   54

函数式 Delete

函数式 delete 是函数式 update 的简化形式。其语法如下：

![t;c;0b;a]        / t is a table, c is a list of where constraints, a is a
                   / list of column names

现在让我们举一个例子来说明函数式 delete 如何工作：

q)![t; enlist (=;`p; 40); 0b;`symbol$()]
                                          / delete from t where p = 40
   n       p
---------------
  msft    38
 samsung  45
  apple   54

打印页面