F# - 数组

---

---

数组是固定大小、从零开始、可变的连续数据元素集合，这些元素都属于相同的类型。

创建数组

您可以使用各种语法和方法或使用 Array 模块中的函数来创建数组。在本节中，我们将讨论在不使用模块函数的情况下创建数组。

在不使用函数的情况下，有三种创建数组的语法方法：

• 列出 [| 和 |] 之间的连续值，并用分号分隔。
• 将每个元素放在单独一行，在这种情况下，分号分隔符是可选的。
• 使用序列表达式。

您可以使用点运算符 (.) 和方括号 ([ 和 ]) 访问数组元素。

以下示例演示了如何创建数组：

//using semicolon separator
let array1 = [| 1; 2; 3; 4; 5; 6 |]
for i in 0 .. array1.Length - 1 do
   printf "%d " array1.[i]
printfn" "

// without semicolon separator
let array2 =
   [|
      1
      2
      3
      4
      5
   |]
for i in 0 .. array2.Length - 1 do
   printf "%d " array2.[i]
printfn" "

//using sequence
let array3 = [| for i in 1 .. 10 -> i * i |]
for i in 0 .. array3.Length - 1 do
   printf "%d " array3.[i]
printfn" "

编译并执行程序时，将生成以下输出：

1 2 3 4 5 6
1 2 3 4 5
1 4 9 16 25 36 49 64 81 100

数组的基本操作

库模块 Microsoft.FSharp.Collections.Array 支持对一维数组的操作。

下表显示了数组的基本操作：

在下一节中，我们将看到其中一些功能的用法。

使用函数创建数组

Array 模块提供了一些从头开始创建数组的函数。

• Array.empty 函数创建一个新的空数组。

• Array.create 函数创建一个指定大小的数组，并将所有元素设置为给定值。

• Array.init 函数创建一个数组，给定一个维度和一个生成元素的函数。

• Array.zeroCreate 函数创建一个数组，其中所有元素都初始化为零值。

• Array.copy 函数创建一个新数组，其中包含从现有数组复制的元素。

• Array.sub 函数从数组的子范围生成一个新数组。

• Array.append 函数通过组合两个现有数组来创建一个新数组。

• Array.choose 函数选择数组的元素以包含在新数组中。

• Array.collect 函数对现有数组的每个数组元素运行指定的函数，然后收集函数生成的元素并将它们组合到一个新数组中。

• Array.concat 函数获取一系列数组并将它们组合成一个数组。

• Array.filter 函数获取一个布尔条件函数，并生成一个新数组，其中只包含输入数组中条件为真的那些元素。

• Array.rev 函数通过反转现有数组的顺序来生成一个新数组。

以下示例演示了这些函数 -

示例 1

(* using create and set *)
let array1 = Array.create 10 ""
for i in 0 .. array1.Length - 1 do
   Array.set array1 i (i.ToString())
for i in 0 .. array1.Length - 1 do
   printf "%s " (Array.get array1 i)
printfn " "

(* empty array *)
let array2 = Array.empty
printfn "Length of empty array: %d" array2.Length

let array3 = Array.create 10 7.0
printfn "Float Array: %A" array3

(* using the init and zeroCreate *)
let array4 = Array.init 10 (fun index -> index * index)
printfn "Array of squares: %A" array4

let array5 : float array = Array.zeroCreate 10
let (myZeroArray : float array) = Array.zeroCreate 10
printfn "Float Array: %A" array5

编译并执行程序时，将生成以下输出：

0 1 2 3 4 5 6 7 8 9
Length of empty array: 0
Float Array: [|7.0; 7.0; 7.0; 7.0; 7.0; 7.0; 7.0; 7.0; 7.0; 7.0|]
Array of squares: [|0; 1; 4; 9; 16; 25; 36; 49; 64; 81|]
Float Array: [|0.0; 0.0; 0.0; 0.0; 0.0; 0.0; 0.0; 0.0; 0.0; 0.0|]

示例 2

(* creating subarray from element 5 *)
(* containing 15 elements thereon *)

let array1 = [| 0 .. 50 |]
let array2 = Array.sub array1 5 15
printfn "Sub Array:"
printfn "%A" array2

(* appending two arrays *)
let array3 = [| 1; 2; 3; 4|]
let array4 = [| 5 .. 9 |]
printfn "Appended Array:"
let array5 = Array.append array3 array4
printfn "%A" array5

(* using the Choose function *)
let array6 = [| 1 .. 20 |]
let array7 = Array.choose (fun elem -> if elem % 3 = 0 then
   Some(float (elem))
      else
   None) array6

printfn "Array with Chosen elements:"
printfn "%A" array7

(*using the Collect function *)
let array8 = [| 2 .. 5 |]
let array9 = Array.collect (fun elem -> [| 0 .. elem - 1 |]) array8
printfn "Array with collected elements:"
printfn "%A" array9

编译并执行程序时，将生成以下输出：

Sub Array:
[|5; 6; 7; 8; 9; 10; 11; 12; 13; 14; 15; 16; 17; 18; 19|]
Appended Array:
[|1; 2; 3; 4; 5; 6; 7; 8; 9|]
Array with Chosen elements:
[|3.0; 6.0; 9.0; 12.0; 15.0; 18.0|]
Array with collected elements:
[|0; 1; 0; 1; 2; 0; 1; 2; 3; 0; 1; 2; 3; 4|]

搜索数组

Array.find 函数获取一个布尔函数，并返回第一个使函数返回 true 的元素，否则引发 KeyNotFoundException。

Array.findIndex 函数的工作方式类似，只是它返回元素的索引而不是元素本身。

以下示例演示了这一点。

Microsoft 提供了这个有趣的程序示例，它查找给定数字范围内第一个既是完全平方数又是完全立方数的元素 -

let array1 = [| 2 .. 100 |]
let delta = 1.0e-10
let isPerfectSquare (x:int) =
   let y = sqrt (float x)
   abs(y - round y) < delta

let isPerfectCube (x:int) =
   let y = System.Math.Pow(float x, 1.0/3.0)
   abs(y - round y) < delta

let element = Array.find (fun elem -> isPerfectSquare elem && isPerfectCube elem) array1

let index = Array.findIndex (fun elem -> isPerfectSquare elem && isPerfectCube elem) array1

printfn "The first element that is both a square and a cube is %d and its index is %d." element index

编译并执行程序时，将生成以下输出：

The first element that is both a square and a cube is 64 and its index is 62.