Pascal - 文件处理

---

---

Pascal 将文件视为一系列组件，这些组件必须具有统一的类型。文件的类型由组件的类型决定。文件数据类型定义如下：

type
file-name = file of base-type;

其中，基本类型指示文件的组件类型。基本类型可以是任何类型，例如整数、实数、布尔值、枚举、子范围、记录、数组和集合，但不能是另一种文件类型。文件类型的变量使用var声明创建：

var
f1, f2,...: file-name;

以下是一些定义文件类型和文件变量的示例：

type
   rfile = file of real;
   ifile = file of integer;
   bfile = file of boolean;
   datafile = file of record
   arrfile = file of array[1..4] of integer;

var
   marks: arrfile;
   studentdata: datafile;
   rainfalldata: rfile;
   tempdata: ifile;
   choices: bfile;

创建和写入文件

让我们编写一个程序，为学生记录创建一个数据文件。它将创建一个名为 students.dat 的文件，并将学生数据写入其中：

program DataFiles;
type
   StudentRecord = Record
      s_name: String;
      s_addr: String;
      s_batchcode: String;
   end;

var
   Student: StudentRecord;
   f: file of StudentRecord;

begin
   Assign(f,'students.dat');
   Rewrite(f);
   Student.s_name := 'John Smith';
   Student.s_addr := 'United States of America';
   Student.s_batchcode := 'Computer Science';
   Write(f,Student);
   Close(f);
end.

编译并运行后，程序将在工作目录中创建一个名为students.dat的文件。您可以使用文本编辑器（如记事本）打开该文件以查看 John Smith 的数据。

从文件读取

我们刚刚创建并写入了一个名为 students.dat 的文件。现在，让我们编写一个程序，从文件中读取学生数据：

program DataFiles;
type
   StudentRecord = Record
      s_name: String;
      s_addr: String;
      s_batchcode: String;
   end;

var
   Student: StudentRecord;
   f: file of StudentRecord;

begin
   assign(f, 'students.dat');
   reset(f); 
   while not eof(f) do
   
   begin
      read(f,Student);
      writeln('Name: ',Student.s_name);
      writeln('Address: ',Student.s_addr);
      writeln('Batch Code: ', Student.s_batchcode);
   end;
   
   close(f);
end.

编译并执行上述代码后，会产生以下结果：

Name: John Smith
Address: United States of America
Batch Code: Computer Science

文件作为子程序参数

Pascal 允许文件变量用作标准和用户定义子程序中的参数。以下示例说明了此概念。该程序创建一个名为 rainfall.txt 的文件并存储一些降雨数据。接下来，它打开文件，读取数据并计算平均降雨量。

请注意，如果将文件参数与子程序一起使用，则必须将其声明为 var 参数。

program addFiledata;
const
   MAX = 4;
type
   raindata = file of real;

var
   rainfile: raindata;
   filename: string;
procedure writedata(var f: raindata);

var
   data: real;
   i: integer;

begin
   rewrite(f, sizeof(data));
   for i:=1 to MAX do
   
   begin
      writeln('Enter rainfall data: ');
      readln(data);
      write(f, data);
   end;
   
   close(f);
end;

procedure computeAverage(var x: raindata);
var
   d, sum: real;
   average: real;

begin
   reset(x);
   sum:= 0.0;
   while not eof(x) do
   
   begin
      read(x, d);
      sum := sum + d;
   end;
   
   average := sum/MAX;
   close(x);
   writeln('Average Rainfall: ', average:7:2);
end;

begin
   writeln('Enter the File Name: ');
   readln(filename);
   assign(rainfile, filename);
   writedata(rainfile);
   computeAverage(rainfile);
end.

编译并执行上述代码后，会产生以下结果：

Enter the File Name:
rainfall.txt
Enter rainfall data:
34
Enter rainfall data:
45
Enter rainfall data:
56
Enter rainfall data:
78
Average Rainfall: 53.25

文本文件

在 Pascal 中，文本文件由字符行组成，每行以换行符结尾。您可以声明和定义此类文件，如下所示：

type
file-name = text;

字符普通文件与文本文件之间的区别在于，文本文件被分成多行，每行都由系统自动插入的特殊换行符终止。以下示例创建并写入一个名为 contact.txt 的文本文件：

program exText;
var
   filename, data: string;
   myfile: text;

begin
   writeln('Enter the file name: ');
   readln(filename);
   
   assign(myfile, filename);
   rewrite(myfile);
   
   writeln(myfile, 'Note to Students: ');
   writeln(myfile, 'For details information on Pascal Programming');
   writeln(myfile, 'Contact: Tutorials Point');
   writeln('Completed writing'); 
   
   close(myfile);
end.

编译并执行上述代码后，会产生以下结果：

Enter the file name:
contact.txt 
Completed writing

追加到文件

追加到文件意味着写入已存在一些数据的文件而不覆盖该文件。以下程序说明了这一点：

program exAppendfile;
var
   myfile: text;
   info: string;

begin
   assign(myfile, 'contact.txt');
   append(myfile);
   
   writeln('Contact Details');
   writeln('webmaster@tutorialspoint.com');
   close(myfile);
   
   (* let us read from this file *)
   assign(myfile, 'contact.txt');
   reset(myfile);
   while not eof(myfile) do
   
   begin
      readln(myfile, info);
      writeln(info);
   end;
   close(myfile);
end.

编译并执行上述代码后，会产生以下结果：

Contact Details
webmaster@tutorialspoint.com
Note to Students:
For details information on Pascal Programming
Contact: Tutorials Point

文件处理函数

Free Pascal 提供以下文件处理函数/过程：