SAS - 饼图

---

---

饼图是用不同颜色表示圆形不同切片来表示值的图形。这些切片都带有标签，并且每个切片对应的数值也显示在图表中。

在 SAS 中，饼图是使用PROC TEMPLATE创建的，它接收用于控制百分比、标签、颜色、标题等的参数。

语法

在 SAS 中创建饼图的基本语法如下：

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = variable /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = ' ';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;

以下是使用参数的描述：

• variable 是我们创建饼图的值。

简单饼图

在这个饼图中，我们从数据集中获取单个变量。饼图是根据切片值创建的，表示变量计数相对于变量总值的比例。

示例

在下面的示例中，每个切片代表汽车类型在汽车总数中的比例。

PROC SQL;
create table CARS1 as
SELECT make, model, type, invoice, horsepower, length, weight
 FROM 
SASHELP.CARS
WHERE make in ('Audi','BMW')
;
RUN;

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上述代码时，我们将获得以下输出：

带数据标签的饼图

在这个饼图中，我们表示每个切片的比例值和百分比值。我们还将标签的位置更改为图表内部。通过使用 DATASKIN 选项修改图表的显示样式。它使用 SAS 环境中提供的内置样式之一。

示例

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上述代码时，我们将获得以下输出：

分组饼图

在这个饼图中，图中显示的变量值根据同一数据集的另一个变量进行分组。每个组都成为一个圆，图表中包含的同心圆的数量与可用组的数量相同。

示例

在下面的示例中，我们根据名为“Make”的变量对图表进行分组。由于有两个可用值（“Audi”和“BMW”），因此我们得到两个同心圆，每个圆在其自己的制造商中代表汽车类型的切片。

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type / Group = make
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上述代码时，我们将获得以下输出：