VB.Net 快速指南

VB.Net - 概述

Visual Basic .NET (VB.NET) 是一种面向对象的计算机编程语言，在 .NET Framework 上实现。虽然它是经典 Visual Basic 语言的演进，但它与 VB6 向后不兼容，任何用旧版本编写的代码都不能在 VB.NET 下编译。

与所有其他 .NET 语言一样，VB.NET 完全支持面向对象的特性。VB.NET 中的一切都是对象，包括所有原始类型（Short、Integer、Long、String、Boolean 等）和用户定义类型、事件，甚至程序集。所有对象都继承自基类 Object。

VB.NET 由微软的 .NET framework 实现。因此，它可以完全访问 .Net Framework 中的所有库。也可以在 Mono 上运行 VB.NET 程序，Mono 是 .NET 的开源替代方案，不仅可以在 Windows 下运行，甚至可以在 Linux 或 Mac OSX 上运行。

以下原因使 VB.Net 成为一种广泛使用的专业语言：

• 现代的，通用的。

• 面向对象的。

• 面向组件的。

• 易于学习。

• 结构化语言。

• 它能生成高效的程序。

• 它可以在各种计算机平台上编译。

• .Net Framework 的一部分。

VB.Net 的强大编程特性

VB.Net 拥有众多强大的编程特性，使其受到全世界众多程序员的喜爱。让我们提一下其中一些特性：

• 布尔条件

• 自动垃圾回收

• 标准库

• 程序集版本控制

• 属性和事件

• 委托和事件管理

• 易于使用的泛型

• 索引器

• 条件编译

• 简单的多线程

VB.Net - 环境设置

在本章中，我们将讨论用于创建 VB.Net 应用程序的工具。

我们已经提到 VB.Net 是 .Net framework 的一部分，用于编写 .Net 应用程序。因此，在讨论运行 VB.Net 程序的可用工具之前，让我们了解 VB.Net 与 .Net framework 的关系。

.Net Framework

.Net framework 是一个革命性的平台，可以帮助您编写以下类型的应用程序：

• Windows 应用程序

• Web 应用程序

• Web 服务

.Net framework 应用程序是多平台应用程序。该框架的设计方式使其可以从以下任何语言使用：Visual Basic、C#、C++、Jscript 和 COBOL 等。

所有这些语言都可以访问框架并相互通信。

.Net framework 包含一个庞大的代码库，供 VB.Net 等客户端语言使用。这些语言使用面向对象的方法。

以下是 .Net framework 的一些组件：

• 公共语言运行时 (CLR)

• .Net Framework 类库

• 公共语言规范

• 公共类型系统

• 元数据和程序集

• Windows 窗体

• ASP.Net 和 ASP.Net AJAX

• ADO.Net

• Windows Workflow Foundation (WF)

• Windows Presentation Foundation

• Windows Communication Foundation (WCF)

• LINQ

有关这些组件各自执行的工作，请参阅 ASP.Net - 简介，有关每个组件的详细信息，请参阅 Microsoft 的文档。

VB.Net 的集成开发环境 (IDE)

Microsoft 提供以下 VB.Net 编程开发工具：

• Visual Studio 2010 (VS)

• Visual Basic 2010 Express (VBE)

• Visual Web Developer

最后两个是免费的。使用这些工具，您可以编写各种 VB.Net 程序，从简单的命令行应用程序到更复杂的应用程序。Visual Basic Express 和 Visual Web Developer Express 版本是 Visual Studio 的精简版本，具有相同的外观和感觉。它们保留了 Visual Studio 的大部分功能。在本教程中，我们使用了 Visual Basic 2010 Express 和 Visual Web Developer（用于 Web 编程章节）。

您可以从 这里 下载。它会自动安装到您的机器上。请注意，安装 Express 版本需要活动的互联网连接。

在 Linux 或 Mac OS 上编写 VB.Net 程序

虽然 .NET Framework 运行在 Windows 操作系统上，但也有一些可在其他操作系统上运行的替代版本。Mono 是 .NET Framework 的一个开源版本，它包含一个 Visual Basic 编译器，并且可以在多个操作系统上运行，包括各种 Linux 和 Mac OS 版本。最新版本是 VB 2012。

Mono 的目标不仅是可以跨平台运行 Microsoft .NET 应用程序，还可以为 Linux 开发人员带来更好的开发工具。Mono 可以运行在许多操作系统上，包括 Android、BSD、iOS、Linux、OS X、Windows、Solaris 和 UNIX。

VB.Net - 程序结构

在我们学习 VB.Net 编程语言的基本构建块之前，让我们先看看一个最基本的 VB.Net 程序结构，以便我们可以在接下来的章节中将其作为参考。

VB.Net Hello World 示例

VB.Net 程序基本上由以下部分组成：

• 命名空间声明

• 一个类或模块

• 一个或多个过程

• 变量

• Main 过程

• 语句和表达式

• 注释

让我们来看一段简单的代码，它将打印“Hello World”字样：

Imports System
Module Module1
   'This program will display Hello World 
   Sub Main()
      Console.WriteLine("Hello World")
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Hello, World!

让我们看看上述程序的各个部分：

• 程序的第一行 **Imports System** 用于在程序中包含 System 命名空间。

• 下一行包含一个 **Module** 声明，即模块 *Module1*。VB.Net 完全面向对象，因此每个程序都必须包含一个模块或类，其中包含程序使用的和过程。

• 类或模块通常包含多个过程。过程包含可执行代码，或者换句话说，它们定义类的行为。过程可以是以下任何一种：

  • 函数

  • 子程序

  • 运算符

  • Get

  • Set

  • AddHandler

  • RemoveHandler

  • RaiseEvent

• 下一行 ('This program) 将被编译器忽略，它被添加是为了在程序中添加额外的注释。

• 下一行定义了 Main 过程，它是所有 VB.Net 程序的入口点。Main 过程声明模块或类执行的操作。

• Main 过程使用以下语句指定其行为：

  **Console.WriteLine("Hello World")** *WriteLine* 是在 *System* 命名空间中定义的 *Console* 类的⼀个方法。此语句导致消息“Hello, World!”显示在屏幕上。

• 最后一行 **Console.ReadKey()** 是为 VS.NET 用户准备的。当程序从 Visual Studio .NET 启动时，这将防止屏幕快速运行并关闭。

编译和执行 VB.Net 程序

如果您使用的是 Visual Studio.Net IDE，请执行以下步骤：

• 启动 Visual Studio。

• 在菜单栏上，选择文件 → 新建 → 项目。

• 从模板中选择 Visual Basic

• 选择控制台应用程序。

• 使用“浏览”按钮指定项目的名称和位置，然后选择“确定”按钮。

• 新项目显示在解决方案资源管理器中。

• 在代码编辑器中编写代码。

• 单击“运行”按钮或按 F5 键运行项目。将出现一个命令提示符窗口，其中包含“Hello World”行。

您可以使用命令行而不是 Visual Studio IDE 来编译 VB.Net 程序：

• 打开文本编辑器并添加上述代码。

• 将文件保存为 **helloworld.vb**

• 打开命令提示符工具并转到保存文件的目录。

• 键入 **vbc helloworld.vb** 并按 Enter 键编译代码。

• 如果代码中没有错误，命令提示符将带您到下一行，并将生成 **helloworld.exe** 可执行文件。

• 接下来，键入 **helloworld** 执行程序。

• 您将能够看到屏幕上打印的“Hello World”。

VB.Net - 基本语法

VB.Net 是一种面向对象的编程语言。在面向对象编程方法中，程序由各种通过操作相互交互的对象组成。对象可以采取的操作称为方法。相同类型的对象被称为具有相同的类型，或者更常见的是，被称为属于相同的类。

当我们考虑 VB.Net 程序时，它可以定义为通过调用彼此的方法进行通信的对象的集合。现在让我们简要地了解一下类、对象、方法和实例变量的含义。

• **对象** - 对象具有状态和行为。例如：狗具有状态——颜色、名称、品种以及行为——摇尾、吠叫、吃东西等。对象是类的实例。

• **类** - 类可以定义为描述其类型对象支持的行为/状态的模板/蓝图。

• **方法** - 方法基本上是一种行为。一个类可以包含许多方法。在方法中编写逻辑、操作数据和执行所有操作。

• **实例变量** - 每个对象都有自己唯一的一组实例变量。对象的状体是由分配给这些实例变量的值创建的。

VB.Net 中的矩形类

例如，让我们考虑一个矩形对象。它具有诸如长度和宽度之类的属性。根据设计，它可能需要接受这些属性的值、计算面积和显示详细信息的方法。

让我们来看一下矩形类的实现，并根据我们在其中的观察结果讨论 VB.Net 的基本语法：

Imports System
Public Class Rectangle
   Private length As Double
   Private width As Double

   'Public methods
   Public Sub AcceptDetails()
      length = 4.5
      width = 3.5
   End Sub

   Public Function GetArea() As Double
      GetArea = length * width
   End Function
   Public Sub Display()
      Console.WriteLine("Length: {0}", length)
      Console.WriteLine("Width: {0}", width)
      Console.WriteLine("Area: {0}", GetArea())

   End Sub

   Shared Sub Main()
      Dim r As New Rectangle()
      r.Acceptdetails()
      r.Display()
      Console.ReadLine()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Length: 4.5
Width: 3.5
Area: 15.75

在上一章中，我们创建了一个包含代码的 Visual Basic 模块。Sub Main 指示 VB.Net 程序的入口点。在这里，我们使用包含代码和数据的类。您可以使用类来创建对象。例如，在代码中，r 是一个 Rectangle 对象。

对象是类的实例：

Dim r As New Rectangle()

类可以拥有从类外部访问的成员，如果这样指定的话。数据成员称为字段，过程成员称为方法。

共享方法或静态方法可以在不创建类对象的情况下调用。实例方法通过类的对象调用 -

Shared Sub Main()
   Dim r As New Rectangle()
   r.Acceptdetails()
   r.Display()
   Console.ReadLine()
End Sub

标识符

标识符是用于标识类、变量、函数或任何其他用户定义项的名称。VB.Net 中命名类的基本规则如下：

• 名称必须以字母开头，后面可以跟一系列字母、数字 (0-9) 或下划线。标识符的第一个字符不能是数字。

• 它不能包含任何嵌入的空格或符号，例如 ? - +! @ # % ^ & * ( ) [ ] { } . ; : " ' / 和 \。但是可以使用下划线 (_) 。

• 它不能是保留关键字。

VB.Net 关键字

下表列出了 VB.Net 保留关键字：

VB.Net - 数据类型

数据类型指的是一个广泛的系统，用于声明不同类型的变量或函数。变量的类型决定了它在存储中占据的空间大小以及如何解释存储的位模式。

VB.Net 中可用的数据类型

VB.Net 提供了广泛的数据类型。下表显示了所有可用的数据类型：

示例

以下示例演示了一些类型的用法：

Module DataTypes
   Sub Main()
      Dim b As Byte
      Dim n As Integer
      Dim si As Single
      Dim d As Double
      Dim da As Date
      Dim c As Char
      Dim s As String
      Dim bl As Boolean
      
      b = 1
      n = 1234567
      si = 0.12345678901234566
      d = 0.12345678901234566
      da = Today
      c = "U"c
      s = "Me"
      
      If ScriptEngine = "VB" Then
         bl = True
      Else
         bl = False
      End If
      
      If bl Then
         'the oath taking
         Console.Write(c & " and," & s & vbCrLf)
         Console.WriteLine("declaring on the day of: {0}", da)
         Console.WriteLine("We will learn VB.Net seriously")
         Console.WriteLine("Lets see what happens to the floating point variables:")
         Console.WriteLine("The Single: {0}, The Double: {1}", si, d)
      End If
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

U and, Me
declaring on the day of: 12/4/2012 12:00:00 PM
We will learn VB.Net seriously
Lets see what happens to the floating point variables:
The Single:0.1234568, The Double: 0.123456789012346

VB.Net 中的类型转换函数

VB.Net 提供以下内联类型转换函数：

示例

以下示例演示了其中一些函数：

Module DataTypes
   Sub Main()
      Dim n As Integer
      Dim da As Date
      Dim bl As Boolean = True
      n = 1234567
      da = Today
      
      Console.WriteLine(bl)
      Console.WriteLine(CSByte(bl))
      Console.WriteLine(CStr(bl))
      Console.WriteLine(CStr(da))
      Console.WriteLine(CChar(CChar(CStr(n))))
      Console.WriteLine(CChar(CStr(da)))
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

True
-1
True
12/4/2012
1
1

VB.Net - 变量

变量只不过是赋予存储区域的名称，我们的程序可以操作它。VB.Net 中的每个变量都有一个特定的类型，它决定了变量内存的大小和布局；可以存储在该内存中的值的范围；以及可以应用于变量的操作集。

我们已经讨论了各种数据类型。VB.Net 中提供的基本值类型可以分为：

VB.Net 还允许定义其他变量值类型，如枚举和变量引用类型，如类。我们将在后续章节中讨论日期类型和类。

VB.Net 中的变量声明

Dim 语句用于声明变量和为一个或多个变量分配存储空间。Dim 语句用于模块、类、结构、过程或块级别。

VB.Net 中变量声明的语法为：

[ < attributelist > ] [ accessmodifier ] [[ Shared ] [ Shadows ] | [ Static ]]
[ ReadOnly ] Dim [ WithEvents ] variablelist

其中：

• attributelist 是应用于变量的属性列表。可选。

• accessmodifier 定义变量的访问级别，其值为 - Public、Protected、Friend、Protected Friend 和 Private。可选。

• Shared 声明共享变量，该变量不与类的任何特定实例关联，而是对类的所有实例可用。可选。

• Shadows 指示变量重新声明并隐藏基类中同名元素或一组重载元素。可选。

• Static 指示即使在声明它的过程终止后，变量也将保留其值。可选。

• ReadOnly 表示变量可以读取，但不能写入。可选。

• WithEvents 指定变量用于响应分配给变量的实例引发的事件。可选。

• Variablelist 提供声明的变量列表。

变量列表中的每个变量都有以下语法和部分：

variablename[ ( [ boundslist ] ) ] [ As [ New ] datatype ] [ = initializer ]

其中：

• variablename - 是变量的名称

• boundslist - 可选。它提供数组变量每个维度的边界列表。

• New - 可选。在 Dim 语句运行时创建类的新的实例。

• datatype - 如果 Option Strict 为 On，则为必需。它指定变量的数据类型。

• initializer - 如果未指定 New，则为可选。在创建变量时计算并赋值给变量的表达式。

这里显示了一些有效的变量声明及其定义：

Dim StudentID As Integer
Dim StudentName As String
Dim Salary As Double
Dim count1, count2 As Integer
Dim status As Boolean
Dim exitButton As New System.Windows.Forms.Button
Dim lastTime, nextTime As Date

VB.Net 中的变量初始化

变量使用等号后跟常量表达式来初始化（赋值）。初始化的一般形式为：

variable_name = value;

例如：

Dim pi As Double
pi = 3.14159

您可以在声明时初始化变量，如下所示：

Dim StudentID As Integer = 100
Dim StudentName As String = "Bill Smith"

示例

尝试以下示例，该示例使用了各种类型的变量：

Module variablesNdataypes
   Sub Main()
      Dim a As Short
      Dim b As Integer
      Dim c As Double
      
      a = 10
      b = 20
      c = a + b
      Console.WriteLine("a = {0}, b = {1}, c = {2}", a, b, c)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

a = 10, b = 20, c = 30

接受用户的输入

System 命名空间中的 Console 类提供了一个ReadLine函数，用于接受用户的输入并将其存储到变量中。例如：

Dim message As String
message = Console.ReadLine

以下示例演示了它：

Module variablesNdataypes
   Sub Main()
      Dim message As String
      Console.Write("Enter message: ")
      message = Console.ReadLine
      Console.WriteLine()
      Console.WriteLine("Your Message: {0}", message)
      Console.ReadLine()
   End Sub
End Module

编译并执行上述代码时，将产生以下结果（假设用户输入 Hello World）：

Enter message: Hello World   
Your Message: Hello World

左值和右值

有两种表达式：

• 左值 - 可以作为赋值的左侧或右侧出现的表达式是左值。

• 右值 - 可以出现在赋值的右侧但不能出现在左侧的表达式是右值。

变量是左值，因此可以出现在赋值的左侧。数字文字是右值，因此不能赋值，也不能出现在左侧。以下是有效语句：

Dim g As Integer = 20

但以下语句无效，将生成编译时错误：

20 = g

VB.Net - 常量和枚举

常量指的是程序在其执行过程中可能不会更改的固定值。这些固定值也称为文字。

常量可以是任何基本数据类型，例如整数常量、浮点常量、字符常量或字符串字面量。还有枚举常量。

常量与普通变量一样，只是它们的定义后值不能修改。

枚举是一组命名的整数常量。

声明常量

在 VB.Net 中，常量使用Const语句声明。Const 语句用于模块、类、结构、过程或块级别，以代替字面值。

Const 语句的语法如下：

[ < attributelist > ] [ accessmodifier ] [ Shadows ] 
Const constantlist

其中：

• attributelist − 指定应用于常量的属性列表；可以使用多个属性，用逗号分隔。可选。

• accessmodifier − 指定哪些代码可以访问这些常量。可选。值可以是：Public、Protected、Friend、Protected Friend 或 Private。

• Shadows − 这使得常量隐藏基类中相同名称的编程元素。可选。

• Constantlist − 给出声明的常量名称列表。必选。

其中，每个常量名称具有以下语法和部分：

constantname [ As datatype ] = initializer

• constantname − 指定常量的名称

• datatype − 指定常量的数 据类型

• initializer − 指定分配给常量的值

例如：

'The following statements declare constants.'
Const maxval As Long = 4999
Public Const message As String = "HELLO" 
Private Const piValue As Double = 3.1415

示例

以下示例演示了常量值的声明和使用：

Module constantsNenum
   Sub Main()
      Const PI = 3.14149
      Dim radius, area As Single
      radius = 7
      area = PI * radius * radius
      Console.WriteLine("Area = " & Str(area))
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Area = 153.933

在 VB.Net 中打印和显示常量

VB.Net 提供以下打印和显示常量：

声明枚举

枚举类型使用Enum语句声明。Enum 语句声明一个枚举并定义其成员的值。Enum 语句可以在模块、类、结构、过程或块级别使用。

Enum 语句的语法如下：

[ < attributelist > ] [ accessmodifier ]  [ Shadows ] 
Enum enumerationname [ As datatype ] 
   memberlist
End Enum

其中：

• attributelist − 指的是应用于变量的属性列表。可选。

• accessmodifier − 指定哪些代码可以访问这些枚举。可选。值可以是：Public、Protected、Friend 或 Private。

• Shadows − 这使得枚举隐藏基类中相同名称的编程元素。可选。

• enumerationname − 枚举的名称。必选

• datatype − 指定枚举及其所有成员的数据类型。

• memberlist − 指定在此语句中声明的成员常量列表。必选。

memberlist 中的每个成员具有以下语法和部分

[< attribute list >] member name [ = initializer ]

其中：

• name − 指定成员的名称。必选。

• initializer − 分配给枚举成员的值。可选。

例如：

Enum Colors
   red = 1
   orange = 2
   yellow = 3
   green = 4
   azure = 5
   blue = 6
   violet = 7
End Enum

示例

以下示例演示了 Enum 变量Colors的声明和使用：

Module constantsNenum
   Enum Colors
      red = 1
      orange = 2
      yellow = 3
      green = 4
      azure = 5
      blue = 6
      violet = 7
   End Enum
   
   Sub Main()
      Console.WriteLine("The Color Red is : " & Colors.red)
      Console.WriteLine("The Color Yellow is : " & Colors.yellow)
      Console.WriteLine("The Color Blue is : " & Colors.blue)
      Console.WriteLine("The Color Green is : " & Colors.green)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

The Color Red is: 1
The Color Yellow is: 3
The Color Blue is: 6
The Color Green is: 4

VB.Net - 修饰符

修饰符是在任何编程元素中添加的关键字，用于对编程元素的行为方式或在程序中的访问方式进行一些特殊强调。

例如，访问修饰符：Public、Private、Protected、Friend、Protected Friend 等，指示编程元素（如变量、常量、枚举或类）的访问级别。

VB.Net 中可用的修饰符列表

下表提供了 VB.Net 修饰符的完整列表：

VB.Net - 语句

语句是 Visual Basic 程序中的完整指令。它可能包含关键字、运算符、变量、字面值、常量和表达式。

语句可以分为：

• 声明语句 − 这些是在其中命名变量、常量或过程的语句，还可以指定数据类型。

• 可执行语句 − 这些是启动操作的语句。这些语句可以调用方法或函数，循环或分支通过代码块，或将值或表达式赋值给变量或常量。在最后一种情况下，它被称为赋值语句。

声明语句

声明语句用于命名和定义过程、变量、属性、数组和常量。声明编程元素时，还可以定义其数据类型、访问级别和作用域。

您可以声明的编程元素包括变量、常量、枚举、类、结构、模块、接口、过程、过程参数、函数返回值、外部过程引用、运算符、属性、事件和委托。

以下是 VB.Net 中的声明语句：

Dim number As Integer
Dim quantity As Integer = 100
Dim message As String = "Hello!"

Const maximum As Long = 1000
Const naturalLogBase As Object 
= CDec(2.7182818284)

Enum CoffeeMugSize
   Jumbo
   ExtraLarge
   Large
   Medium
   Small
End Enum 

Class Box
Public length As Double
Public breadth As Double   
Public height As Double
End Class

Structure Box
Public length As Double           
Public breadth As Double   
Public height As Double
End Structure

Public Module myModule
Sub Main()
Dim user As String = 
InputBox("What is your name?") 
MsgBox("User name is" & user)
End Sub 
End Module

Public Interface MyInterface
   Sub doSomething()
End Interface 

Function myFunction
(ByVal n As Integer) As Double 
   Return 5.87 * n
End Function

Sub mySub(ByVal s As String)
   Return
End Sub 

Declare Function getUserName
Lib "advapi32.dll" 
Alias "GetUserNameA" 
(
   ByVal lpBuffer As String, 
   ByRef nSize As Integer) As Integer 

Public Shared Operator +
(ByVal x As obj, ByVal y As obj) As obj
   Dim r As New obj
' implemention code for r = x + y
   Return r
End Operator 

ReadOnly Property quote() As String 
   Get 
      Return quoteString
   End Get 
End Property

Public Event Finished()

Delegate Function MathOperator( 
   ByVal x As Double, 
   ByVal y As Double 
) As Double 

可执行语句

可执行语句执行操作。调用过程、分支到代码中的其他位置、循环遍历多个语句或计算表达式的语句都是可执行语句。赋值语句是可执行语句的特例。

示例

以下示例演示了决策语句：

Module decisions
   Sub Main()
      'local variable definition '
      Dim a As Integer = 10

      ' check the boolean condition using if statement '
      If (a < 20) Then
         ' if condition is true then print the following '
         Console.WriteLine("a is less than 20")
      End If
      Console.WriteLine("value of a is : {0}", a)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

a is less than 20;
value of a is : 10

VB.Net - 指令

VB.Net 编译器指令指示编译器在实际编译开始之前预处理信息。所有这些指令都以 # 开头，一行指令前只能出现空格字符。这些指令不是语句。

VB.Net 编译器没有单独的预处理器；但是，这些指令的处理方式就好像有一个预处理器一样。在 VB.Net 中，编译器指令用于帮助进行条件编译。与 C 和 C++ 指令不同，它们不用于创建宏。

VB.Net 中的编译器指令

VB.Net 提供以下编译器指令集：

• #Const 指令

• #ExternalSource 指令

• #If...Then...#Else 指令

• #Region 指令

#Const 指令

此指令定义条件编译常量。此指令的语法如下：

#Const constname = expression

其中：

• constname − 指定常量的名称。必需。

• expression − 它可以是字面量，也可以是其他条件编译常量，或者包括任何或所有算术或逻辑运算符（除 Is 外）的组合。

例如：

#Const state = "WEST BENGAL"

示例

以下代码演示了该指令的假设用法：

Module mydirectives
#Const age = True
Sub Main()
   #If age Then
      Console.WriteLine("You are welcome to the Robotics Club")
   #End If
   Console.ReadKey()
End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

You are welcome to the Robotics Club

#ExternalSource 指令

此指令用于指示源代码特定行与源代码外部文本之间的映射。它仅由编译器使用，调试器对代码编译没有影响。

此指令用于将来自外部代码文件的外部代码包含到源代码文件中。

此指令的语法如下：

#ExternalSource( StringLiteral , IntLiteral )
   [ LogicalLine ]
#End ExternalSource

#ExternalSource 指令的参数是外部文件的路径、第一行的行号以及发生错误的行。

示例

以下代码演示了该指令的假设用法：

Module mydirectives
   Public Class ExternalSourceTester

      Sub TestExternalSource()

      #ExternalSource("c:\vbprogs\directives.vb", 5)
         Console.WriteLine("This is External Code. ")
      #End ExternalSource

      End Sub
   End Class

   Sub Main()
      Dim t As New ExternalSourceTester()
      t.TestExternalSource()
      Console.WriteLine("In Main.")
      Console.ReadKey()

   End Sub

当上述代码编译并执行时，它会产生以下结果：

This is External Code.
In Main.

#If...Then...#Else 指令

此指令有条件地编译选定的 Visual Basic 代码块。

此指令的语法如下：

#If expression Then
   statements
[ #ElseIf expression Then
   [ statements ]
...
#ElseIf expression Then
   [ statements ] ]
[ #Else
   [ statements ] ]
#End If

例如：

#Const TargetOS = "Linux"
#If TargetOS = "Windows 7" Then
   ' Windows 7 specific code
#ElseIf TargetOS = "WinXP" Then
   ' Windows XP specific code
#Else
   ' Code for other OS
#End if

示例

以下代码演示了该指令的假设用法：

Module mydirectives
#Const classCode = 8

   Sub Main()
   #If classCode = 7 Then
      Console.WriteLine("Exam Questions for Class VII")
   #ElseIf classCode = 8 Then
      Console.WriteLine("Exam Questions for Class VIII")
   #Else
      Console.WriteLine("Exam Questions for Higher Classes")
   #End If
      Console.ReadKey()

   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Exam Questions for Class VIII

#Region 指令

此指令有助于折叠和隐藏 Visual Basic 文件中的代码部分。

此指令的语法如下：

#Region "identifier_string" 
#End Region

例如：

#Region "StatsFunctions" 
   ' Insert code for the Statistical functions here.
#End Region

VB.Net - 运算符

运算符是告诉编译器执行特定数学或逻辑操作的符号。VB.Net 运算符丰富，并提供以下类型的常用运算符：

• 算术运算符

• 比较运算符

• 逻辑/按位运算符

• 位移运算符

• 赋值运算符

• 其他运算符

本教程将解释最常用的运算符。

算术运算符

下表显示了 VB.Net 支持的所有算术运算符。假设变量 A 为 2，变量 B 为 7，则：

显示示例

比较运算符

下表显示了 VB.Net 支持的所有比较运算符。假设变量 A 为 10，变量 B 为 20，则：

显示示例

除了上述内容外，VB.Net 还提供了三个比较运算符，我们将在接下来的章节中使用它们；但是，我们在此简要介绍一下。

• Is 运算符 − 它比较两个对象引用变量，并确定两个对象引用是否引用同一个对象，而无需执行值比较。如果 object1 和 object2 都引用完全相同的对象实例，则结果为 True；否则，结果为 False。

• IsNot 运算符 − 它也比较两个对象引用变量，并确定两个对象引用是否引用不同的对象。如果 object1 和 object2 都引用完全相同的对象实例，则结果为 False；否则，结果为 True。

• Like 运算符 − 它将字符串与模式进行比较。

逻辑/按位运算符

下表显示了 VB.Net 支持的所有逻辑运算符。假设变量 A 为布尔值 True，变量 B 为布尔值 False，则：

显示示例

位移运算符

我们已经讨论了按位运算符。位移运算符对二进制值执行移位操作。在进入位移运算符之前，让我们了解一下位操作。

按位运算符作用于位并执行逐位操作。&，| 和 ^ 的真值表如下：

假设 A = 60；B = 13；现在以二进制格式，它们将如下所示：

A = 0011 1100

B = 0000 1101

-----------------

A&B = 0000 1100

A|B = 0011 1101

A^B = 0011 0001

~A = 1100 0011

我们已经看到 VB.Net 支持的按位运算符是 And、Or、Xor 和 Not。位移运算符分别是 >> 和 <<，分别用于左移和右移。

假设变量 A 为 60，变量 B 为 13，则：

显示示例

赋值运算符

VB.Net支持以下赋值运算符：

显示示例

其他运算符

VB.Net还支持一些其他重要的运算符。

显示示例

AddHandler Button1.Click,
AddressOf Button1_Click

 
Dim result As res
= Await AsyncMethodThatReturnsResult()
Await AsyncMethod()

MsgBox(GetType(Integer).ToString())

Dim add5 = Function(num As
   Integer) num + 5
'prints 10
Console.WriteLine(add5(5))

Dim num = 5
Console.WriteLine(If(num >= 0,
"Positive", "Negative"))

VB.Net中的运算符优先级

运算符优先级决定表达式中项的分组方式。这会影响表达式的求值方式。某些运算符的优先级高于其他运算符；例如，乘法运算符的优先级高于加法运算符：

例如，x = 7 + 3 * 2；这里，x被赋值为13，而不是20，因为运算符*的优先级高于+，所以它首先与3*2相乘，然后加到7中。

表中列出了优先级最高的运算符位于顶部，优先级最低的运算符位于底部。在表达式中，将首先计算优先级较高的运算符。

显示示例

VB.Net - 决策

决策结构要求程序员指定一个或多个条件供程序评估或测试，以及在确定条件为真时要执行的语句（或语句组），以及可选地在确定条件为假时要执行的其他语句。

以下是大多数编程语言中典型的决策结构的通用形式：

VB.Net提供以下类型的决策语句。点击以下链接查看详细信息。

VB.Net - 循环

可能需要多次执行一段代码的情况。通常情况下，语句是顺序执行的：函数中的第一个语句先执行，然后是第二个语句，依此类推。

编程语言提供各种控制结构，允许更复杂的执行路径。

循环语句允许我们多次执行一个语句或一组语句，以下是大多数编程语言中循环语句的通用形式：

VB.Net提供以下类型的循环来处理循环需求。点击以下链接查看详细信息。

循环控制语句

循环控制语句会改变执行的正常顺序。当执行离开作用域时，在该作用域中创建的所有自动对象都会被销毁。

VB.Net 提供以下控制语句。点击以下链接查看详细信息。

VB.Net - 字符串

在 VB.Net 中，您可以使用字符串作为字符数组，但是更常见的做法是使用 String 关键字声明字符串变量。String 关键字是System.String类的别名。

创建字符串对象

您可以使用以下方法之一创建字符串对象：

• 将字符串文字赋值给 String 变量

• 使用 String 类构造函数

• 使用字符串连接运算符 (+)

• 检索返回字符串的属性或调用方法

• 调用格式化方法将值或对象转换为其字符串表示形式

以下示例演示了这一点：

Module strings
   Sub Main()
      Dim fname, lname, fullname, greetings As String
      fname = "Rowan"
      lname = "Atkinson"
      fullname = fname + " " + lname
      Console.WriteLine("Full Name: {0}", fullname)

      'by using string constructor
      Dim letters As Char() = {"H", "e", "l", "l", "o"}
      greetings = New String(letters)
      Console.WriteLine("Greetings: {0}", greetings)

      'methods returning String
      Dim sarray() As String = {"Hello", "From", "Tutorials", "Point"}
      Dim message As String = String.Join(" ", sarray)
      Console.WriteLine("Message: {0}", message)

      'formatting method to convert a value 
      Dim waiting As DateTime = New DateTime(2012, 12, 12, 17, 58, 1)
      Dim chat As String = String.Format("Message sent at {0:t} on {0:D}", waiting)
      Console.WriteLine("Message: {0}", chat)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Full Name: Rowan Atkinson
Greetings: Hello
Message: Hello From Tutorials Point
Message: Message sent at 5:58 PM on Wednesday, December 12, 2012

String 类的属性

String 类具有以下两个属性：

String 类的使用方法

String 类有许多方法可以帮助您处理字符串对象。下表提供了一些最常用的方法：

以上方法列表并不完整，请访问 MSDN 库查看完整的方法和 String 类构造函数列表。

示例

以下示例演示了上面提到的一些方法：

字符串比较

Module strings
   Sub Main()
      Dim str1, str2 As String
      str1 = "This is test"
      str2 = "This is text"
      
      If (String.Compare(str1, str2) = 0) Then
         Console.WriteLine(str1 + " and " + str2 + " are equal.")
      Else
         Console.WriteLine(str1 + " and " + str2 + " are not equal.")
      End If
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

This is test and This is text are not equal.

字符串包含字符串

Module strings
   Sub Main()
      Dim str1 As String
      str1 = "This is test"
      
      If (str1.Contains("test")) Then
         Console.WriteLine("The sequence 'test' was found.")
      End If
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

The sequence 'test' was found.

获取子字符串

Module strings
   Sub Main()
      Dim str As String
      str = "Last night I dreamt of San Pedro"
      Console.WriteLine(str)
      
      Dim substr As String = str.Substring(23)
      Console.WriteLine(substr)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Last night I dreamt of San Pedro
San Pedro.

连接字符串

Module strings
   Sub Main()
      Dim strarray As String() = {
         "Down the way where the nights are gay",
         "And the sun shines daily on the mountain top",
         "I took a trip on a sailing ship",
         "And when I reached Jamaica",
         "I made a stop"
      }
      Dim str As String = String.Join(vbCrLf, strarray)
      Console.WriteLine(str)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Down the way where the nights are gay
And the sun shines daily on the mountain top
I took a trip on a sailing ship
And when I reached Jamaica
I made a stop

VB.Net - 日期和时间

您编写的许多软件都需要实现某种形式的日期函数，以返回当前日期和时间。日期在日常生活中如此普遍，以至于在不经思考的情况下就可以轻松地使用它们。VB.Net 还提供了强大的日期运算工具，使日期操作变得容易。

**Date** 数据类型包含日期值、时间值或日期和时间值。Date 的默认值为 0001 年 1 月 1 日的午夜 (0:00:00)。等效的 .NET 数据类型为 **System.DateTime**。

**DateTime** 结构表示时间中的一个瞬间，通常表示为日期和时间。

'Declaration
<SerializableAttribute> _
Public Structure DateTime _
   Implements IComparable, IFormattable, IConvertible, ISerializable,  
   IComparable(Of DateTime), IEquatable(Of DateTime)

您还可以从 DateAndTime 类获取当前日期和时间。

**DateAndTime** 模块包含在日期和时间操作中使用的过程和属性。

'Declaration
<StandardModuleAttribute> _
Public NotInheritable Class DateAndTime

DateTime 结构的属性和方法

下表列出了 **DateTime** 结构的一些常用**属性**：

下表列出了 **DateTime** 结构的一些常用**方法**：

以上方法列表并不完整，请访问 Microsoft 文档 查看 DateTime 结构的完整方法和属性列表。

创建 DateTime 对象

您可以通过以下方式之一创建 DateTime 对象：

• 从任何重载的 DateTime 构造函数调用 DateTime 构造函数。

• 将 DateTime 对象分配给由属性或方法返回的日期和时间值。

• 分析日期和时间值的字符串表示形式。

• 调用 DateTime 结构的隐式默认构造函数。

以下示例演示了这一点：

Module Module1
   Sub Main()
      'DateTime constructor: parameters year, month, day, hour, min, sec
      Dim date1 As New Date(2012, 12, 16, 12, 0, 0)
      'initializes a new DateTime value
      Dim date2 As Date = #12/16/2012 12:00:52 AM#
      'using properties
      Dim date3 As Date = Date.Now
      Dim date4 As Date = Date.UtcNow
      Dim date5 As Date = Date.Today
      
      Console.WriteLine(date1)
      Console.WriteLine(date2)
      Console.WriteLine(date3)
      Console.WriteLine(date4)
      Console.WriteLine(date5)
      Console.ReadKey()
   End Sub
End Module

编译并执行上述代码后，会产生以下结果：

12/16/2012 12:00:00 PM
12/16/2012 12:00:52 PM
12/12/2012 10:22:50 PM
12/12/2012 12:00:00 PM

获取当前日期和时间

以下程序演示如何在 VB.Net 中获取当前日期和时间：

Module dateNtime
   Sub Main()
      Console.Write("Current Time: ")
      Console.WriteLine(Now.ToLongTimeString)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Current Time: 11 :05 :32 AM

当前日期：

Module dateNtime
   Sub Main()
      Console.WriteLine("Current Date: ")
      Dim dt As Date = Today
      Console.WriteLine("Today is: {0}", dt)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Today is: 12/11/2012 12:00:00 AM

日期格式化

日期文字应括在井号 (# #) 中，并以 M/d/yyyy 格式指定，例如 #12/16/2012#。否则，您的代码可能会根据运行应用程序的区域设置而变化。

例如，您为 2012 年 2 月 6 日指定了日期文字 #2/6/2012#。对于使用 mm/dd/yyyy 格式的区域设置来说是可以的。但是，在使用 dd/mm/yyyy 格式的区域设置中，您的文字将编译为 2012 年 6 月 2 日。如果区域设置使用其他格式，例如 yyyy/mm/dd，则文字将无效并导致编译器错误。

要将日期文字转换为您的区域设置的格式或自定义格式，请使用 String 类的 **Format** 函数，指定预定义或用户定义的日期格式。

以下示例演示了这一点。

Module dateNtime
   Sub Main()
      Console.WriteLine("India Wins Freedom: ")
      Dim independenceDay As New Date(1947, 8, 15, 0, 0, 0)
      ' Use format specifiers to control the date display.
      Console.WriteLine(" Format 'd:' " & independenceDay.ToString("d"))
      Console.WriteLine(" Format 'D:' " & independenceDay.ToString("D"))
      Console.WriteLine(" Format 't:' " & independenceDay.ToString("t"))
      Console.WriteLine(" Format 'T:' " & independenceDay.ToString("T"))
      Console.WriteLine(" Format 'f:' " & independenceDay.ToString("f"))
      Console.WriteLine(" Format 'F:' " & independenceDay.ToString("F"))
      Console.WriteLine(" Format 'g:' " & independenceDay.ToString("g"))
      Console.WriteLine(" Format 'G:' " & independenceDay.ToString("G"))
      Console.WriteLine(" Format 'M:' " & independenceDay.ToString("M"))
      Console.WriteLine(" Format 'R:' " & independenceDay.ToString("R"))
      Console.WriteLine(" Format 'y:' " & independenceDay.ToString("y"))
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

India Wins Freedom:
Format 'd:' 8/15/1947
Format 'D:' Friday, August 15, 1947
Format 't:' 12:00 AM
Format 'T:' 12:00:00 AM
Format 'f:' Friday, August 15, 1947 12:00 AM
Format 'F:' Friday, August 15, 1947 12:00:00 AM
Format 'g:' 8/15/1947 12:00 AM
Format 'G:' 8/15/1947 12:00:00 AM
Format 'M:' 8/15/1947 August 15
Format 'R:' Fri, 15 August 1947 00:00:00 GMT
Format 'y:' August, 1947

预定义的日期/时间格式

下表标识了预定义的日期和时间格式名称。这些名称可以用作 **Format** 函数的 style 参数：

对于其他格式，例如用户定义的格式，请参阅 Microsoft 文档。

DateAndTime 类的属性和方法

下表列出了一些常用的DateAndTime 类的属性：

下表列出了一些常用的DateAndTime类的方法：

以上列表并不详尽。有关 DateAndTime 类的属性和方法的完整列表，请参阅 Microsoft 文档。

以下程序演示了一些这些属性和方法：

Module Module1
   Sub Main()
      Dim birthday As Date
      Dim bday As Integer
      Dim month As Integer
      Dim monthname As String
      ' Assign a date using standard short format.
      birthday = #7/27/1998#
      bday = Microsoft.VisualBasic.DateAndTime.Day(birthday)
      month = Microsoft.VisualBasic.DateAndTime.Month(birthday)
      monthname = Microsoft.VisualBasic.DateAndTime.MonthName(month)
      
      Console.WriteLine(birthday)
      Console.WriteLine(bday)
      Console.WriteLine(month)
      Console.WriteLine(monthname)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

7/27/1998 12:00:00 AM
27
7
July

VB.Net - 数组

数组存储相同类型元素的固定大小的顺序集合。数组用于存储数据集合，但通常更有效地将数组视为相同类型的变量集合。

所有数组都由连续的内存位置组成。最低地址对应于第一个元素，最高地址对应于最后一个元素。

在 VB.Net 中创建数组

要在 VB.Net 中声明数组，可以使用 Dim 语句。例如，

Dim intData(30)	  ' an array of 31 elements
Dim strData(20) As String	' an array of 21 strings
Dim twoDarray(10, 20) As Integer	'a two dimensional array of integers
Dim ranges(10, 100)	 'a two dimensional array

您也可以在声明数组时初始化数组元素。例如，

Dim intData() As Integer = {12, 16, 20, 24, 28, 32}
Dim names() As String = {"Karthik", "Sandhya", _
"Shivangi", "Ashwitha", "Somnath"}
Dim miscData() As Object = {"Hello World", 12d, 16ui, "A"c}

可以使用数组的索引来存储和访问数组中的元素。以下程序演示了这一点：

Module arrayApl
   Sub Main()
      Dim n(10) As Integer ' n is an array of 11 integers '
      Dim i, j As Integer
      ' initialize elements of array n '         
      
      For i = 0 To 10
          n(i) = i + 100 ' set element at location i to i + 100 
      Next i
      ' output each array element's value '
      
      For j = 0 To 10
          Console.WriteLine("Element({0}) = {1}", j, n(j))
      Next j
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Element(0) = 100
Element(1) = 101
Element(2) = 102
Element(3) = 103
Element(4) = 104
Element(5) = 105
Element(6) = 106
Element(7) = 107
Element(8) = 108
Element(9) = 109
Element(10) = 110

动态数组

动态数组是可以根据程序需要进行维度化和重新维度化的数组。可以使用ReDim语句声明动态数组。

ReDim 语句的语法：

ReDim [Preserve] arrayname(subscripts)

其中：

• Preserve关键字有助于在调整动态数组大小时保留现有数组中的数据。

• arrayname是要重新维度化的数组的名称。

• subscripts指定新的维度。

Module arrayApl
   Sub Main()
      Dim marks() As Integer
      ReDim marks(2)
      marks(0) = 85
      marks(1) = 75
      marks(2) = 90
     
      ReDim Preserve marks(10)
      marks(3) = 80
      marks(4) = 76
      marks(5) = 92
      marks(6) = 99
      marks(7) = 79
      marks(8) = 75
      
      For i = 0 To 10
         Console.WriteLine(i & vbTab & marks(i))
      Next i
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

0	85
1	75
2	90
3	80
4	76
5	92
6	99
7	79
8	75
9	0
10	0

多维数组

VB.Net 允许使用多维数组。多维数组也称为矩形数组。

您可以声明一个二维字符串数组，如下所示：

Dim twoDStringArray(10, 20) As String

或者，一个三维整数变量数组：

Dim threeDIntArray(10, 10, 10) As Integer

以下程序演示了创建和使用二维数组：

Module arrayApl
   Sub Main()
      ' an array with 5 rows and 2 columns
      Dim a(,) As Integer = {{0, 0}, {1, 2}, {2, 4}, {3, 6}, {4, 8}}
      Dim i, j As Integer
      ' output each array element's value '
      
      For i = 0 To 4
          For j = 0 To 1
              Console.WriteLine("a[{0},{1}] = {2}", i, j, a(i, j))
          Next j
      Next i
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

a[0,0]: 0
a[0,1]: 0
a[1,0]: 1
a[1,1]: 2
a[2,0]: 2
a[2,1]: 4
a[3,0]: 3
a[3,1]: 6
a[4,0]: 4
a[4,1]: 8

锯齿数组

锯齿数组是数组的数组。以下代码显示了声明名为 *scores* 的整数锯齿数组：

Dim scores As Integer()() = New Integer(5)(){}

以下示例说明了如何使用锯齿数组：

Module arrayApl
   Sub Main()
      'a jagged array of 5 array of integers
      Dim a As Integer()() = New Integer(4)() {}
      a(0) = New Integer() {0, 0}
      a(1) = New Integer() {1, 2}
      a(2) = New Integer() {2, 4}
      a(3) = New Integer() {3, 6}
      a(4) = New Integer() {4, 8}
      Dim i, j As Integer
      ' output each array element's value 
      
      For i = 0 To 4
         For j = 0 To 1
            Console.WriteLine("a[{0},{1}] = {2}", i, j, a(i)(j))
         Next j
      Next i
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

a[0][0]: 0
a[0][1]: 0
a[1][0]: 1
a[1][1]: 2
a[2][0]: 2
a[2][1]: 4
a[3][0]: 3
a[3][1]: 6
a[4][0]: 4
a[4][1]: 8

Array 类

Array 类是 VB.Net 中所有数组的基类。它在 System 命名空间中定义。Array 类提供了各种属性和方法来处理数组。

Array 类的属性

下表提供了一些最常用的Array类的属性：

获取 Array 的秩（维度数）。

Array 类的方 法

ToString()

示例

返回表示当前对象的字符串（继承自 Object）。

Module arrayApl
   Sub Main()
      Dim list As Integer() = {34, 72, 13, 44, 25, 30, 10}
      Dim temp As Integer() = list
      Dim i As Integer
      Console.Write("Original Array: ")
      
      For Each i In list
         Console.Write("{0} ", i)
      Next i
      Console.WriteLine()
      ' reverse the array
      Array.Reverse(temp)
      Console.Write("Reversed Array: ")
      
      For Each i In temp
         Console.Write("{0} ", i)
      Next i
      Console.WriteLine()
      'sort the array
      Array.Sort(list)
      Console.Write("Sorted Array: ")
      
      For Each i In list
         Console.Write("{0} ", i)
      Next i
      Console.WriteLine()
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Original Array: 34 72 13 44 25 30 10
Reversed Array: 10 30 25 44 13 72 34
Sorted Array: 10 13 25 30 34 44 72

VB.Net - 集合

有关 Array 类属性和方法的完整列表，请参阅 Microsoft 文档。

以下程序演示了 Array 类的一些方法的使用

集合类是用于数据存储和检索的专用类。这些类提供对堆栈、队列、列表和哈希表的支持。大多数集合类实现相同的接口。

集合类具有多种用途，例如动态地为元素分配内存以及基于索引访问项目列表等。这些类创建 Object 类的对象集合，Object 类是 VB.Net 中所有数据类型的基类。

VB.Net - 函数

过程是一组语句，当被调用时，这些语句一起执行一个任务。过程执行完毕后，控制权返回到调用该过程的语句。VB.Net 有两种类型的过程：

• 函数 (Functions)

• 子过程或子程序 (Sub procedures or Subs)

函数返回一个值，而子程序不返回值。

定义函数 (Defining a Function)

Function 语句用于声明函数的名称、参数和主体。Function 语句的语法如下：

[Modifiers] Function FunctionName [(ParameterList)] As ReturnType
   [Statements]
End Function

其中：

• 修饰符 (Modifiers) − 指定函数的访问级别；可能的值包括：Public、Private、Protected、Friend、Protected Friend，以及关于重载、覆盖、共享和隐藏的信息。

• 函数名 (FunctionName) − 指示函数的名称

• 参数列表 (ParameterList) − 指定参数列表

• 返回类型 (ReturnType) − 指定函数返回的变量的数据类型

示例

以下代码片段显示了一个函数 FindMax，它接受两个整数值并返回两者中较大的一个。

Function FindMax(ByVal num1 As Integer, ByVal num2 As Integer) As Integer
   ' local variable declaration */
   Dim result As Integer
   
   If (num1 > num2) Then
      result = num1
   Else
      result = num2
   End If
   FindMax = result
End Function

函数返回值 (Function Returning a Value)

在 VB.Net 中，函数可以通过两种方式将值返回给调用代码：

• 使用 return 语句

• 将值赋给函数名

以下示例演示了如何使用 FindMax 函数：

Module myfunctions
   Function FindMax(ByVal num1 As Integer, ByVal num2 As Integer) As Integer
      ' local variable declaration */
      Dim result As Integer
      
      If (num1 > num2) Then
         result = num1
      Else
         result = num2
      End If
      FindMax = result
   End Function
   Sub Main()
      Dim a As Integer = 100
      Dim b As Integer = 200
      Dim res As Integer
      
      res = FindMax(a, b)
      Console.WriteLine("Max value is : {0}", res)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Max value is : 200

递归函数 (Recursive Function)

函数可以调用自身。这称为递归。以下是一个使用递归函数计算给定数字阶乘的示例：

Module myfunctions
   Function factorial(ByVal num As Integer) As Integer
      ' local variable declaration */
      Dim result As Integer
      
      If (num = 1) Then
         Return 1
      Else
         result = factorial(num - 1) * num
         Return result
      End If
   End Function
   Sub Main()
      'calling the factorial method
      Console.WriteLine("Factorial of 6 is : {0}", factorial(6))
      Console.WriteLine("Factorial of 7 is : {0}", factorial(7))
      Console.WriteLine("Factorial of 8 is : {0}", factorial(8))
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Factorial of 6 is: 720
Factorial of 7 is: 5040
Factorial of 8 is: 40320

参数数组 (Param Arrays)

有时，在声明函数或子过程时，您不确定作为参数传递的参数数量。VB.Net 参数数组（或参数数组）在这种情况下很有帮助。

以下示例演示了这一点：

Module myparamfunc
   Function AddElements(ParamArray arr As Integer()) As Integer
      Dim sum As Integer = 0
      Dim i As Integer = 0
      
      For Each i In arr
         sum += i
      Next i
      Return sum
   End Function
   Sub Main()
      Dim sum As Integer
      sum = AddElements(512, 720, 250, 567, 889)
      Console.WriteLine("The sum is: {0}", sum)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

The sum is: 2938

将数组作为函数参数传递 (Passing Arrays as Function Arguments)

您可以在 VB.Net 中将数组作为函数参数传递。以下示例演示了这一点：

Module arrayParameter
   Function getAverage(ByVal arr As Integer(), ByVal size As Integer) As Double
      'local variables
      Dim i As Integer
      Dim avg As Double
      Dim sum As Integer = 0
      
      For i = 0 To size - 1
         sum += arr(i)
      Next i
      avg = sum / size
      Return avg
   End Function
   Sub Main()
      ' an int array with 5 elements '
      Dim balance As Integer() = {1000, 2, 3, 17, 50}
      Dim avg As Double
      'pass pointer to the array as an argument 
      avg = getAverage(balance, 5)
      ' output the returned value '
      Console.WriteLine("Average value is: {0} ", avg)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Average value is: 214.4

VB.Net - 子过程 (Sub Procedures)

正如我们在上一章中提到的，子过程是不返回值的过程。在我们所有的示例中，我们一直在使用 Sub 过程 Main。到目前为止，我们在这些教程中一直在编写控制台应用程序。当这些应用程序启动时，控制权将转到 Main 子过程，然后它依次运行构成程序主体的任何其他语句。

定义子过程 (Defining Sub Procedures)

Sub 语句用于声明子过程的名称、参数和主体。Sub 语句的语法如下：

[Modifiers] Sub SubName [(ParameterList)] 
   [Statements]
End Sub

其中：

• 修饰符 (Modifiers) − 指定过程的访问级别；可能的值包括：Public、Private、Protected、Friend、Protected Friend，以及关于重载、覆盖、共享和隐藏的信息。

• 子程序名 (SubName) − 指示 Sub 的名称

• 参数列表 (ParameterList) − 指定参数列表

示例

以下示例演示了一个子过程 CalculatePay，它接受两个参数 hours 和 wages 并显示员工的总工资：

Module mysub
   Sub CalculatePay(ByRef hours As Double, ByRef wage As Decimal)
      'local variable declaration
      Dim pay As Double
      pay = hours * wage
      Console.WriteLine("Total Pay: {0:C}", pay)
   End Sub
   Sub Main()
      'calling the CalculatePay Sub Procedure
      CalculatePay(25, 10)
      CalculatePay(40, 20)
      CalculatePay(30, 27.5)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Total Pay: $250.00
Total Pay: $800.00
Total Pay: $825.00

按值传递参数 (Passing Parameters by Value)

这是将参数传递给方法的默认机制。在这种机制中，当调用方法时，将为每个值参数创建一个新的存储位置。实际参数的值将复制到其中。因此，对方法内部参数所做的更改不会影响参数。

在 VB.Net 中，您可以使用ByVal关键字声明引用参数。以下示例演示了这个概念：

Module paramByval
   Sub swap(ByVal x As Integer, ByVal y As Integer)
      Dim temp As Integer
      temp = x ' save the value of x 
      x = y    ' put y into x 
      y = temp 'put temp into y 
   End Sub
   Sub Main()
      ' local variable definition 
      Dim a As Integer = 100
      Dim b As Integer = 200
      Console.WriteLine("Before swap, value of a : {0}", a)
      Console.WriteLine("Before swap, value of b : {0}", b)
      ' calling a function to swap the values '
      swap(a, b)
      Console.WriteLine("After swap, value of a : {0}", a)
      Console.WriteLine("After swap, value of b : {0}", b)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Before swap, value of a :100
Before swap, value of b :200
After swap, value of a :100
After swap, value of b :200

它表明尽管值在函数内部已更改，但值并没有改变。

按引用传递参数 (Passing Parameters by Reference)

引用参数是指向变量的内存位置的引用。当您按引用传递参数时，与值参数不同，不会为这些参数创建新的存储位置。引用参数表示与提供给方法的实际参数相同的内存位置。

在 VB.Net 中，您可以使用ByRef关键字声明引用参数。以下示例演示了这一点：

Module paramByref
   Sub swap(ByRef x As Integer, ByRef y As Integer)
      Dim temp As Integer
      temp = x ' save the value of x 
      x = y    ' put y into x 
      y = temp 'put temp into y 
   End Sub
   Sub Main()
      ' local variable definition 
      Dim a As Integer = 100
      Dim b As Integer = 200
      Console.WriteLine("Before swap, value of a : {0}", a)
      Console.WriteLine("Before swap, value of b : {0}", b)
      ' calling a function to swap the values '
      swap(a, b)
      Console.WriteLine("After swap, value of a : {0}", a)
      Console.WriteLine("After swap, value of b : {0}", b)
      Console.ReadLine()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Before swap, value of a : 100
Before swap, value of b : 200
After swap, value of a : 200
After swap, value of b : 100

VB.Net - 类和对象

当您定义一个类时，您定义了一种数据类型的蓝图。这实际上并没有定义任何数据，但它确实定义了类名的含义，即类的对象将包含什么以及可以在此类对象上执行什么操作。

对象是类的实例。构成类的成员函数和变量称为类的成员。

类定义 (Class Definition)

类定义以关键字Class开头，后跟类名；以及类体，以 End Class 语句结束。以下是类定义的一般形式：

[ <attributelist> ] [ accessmodifier ] [ Shadows ] [ MustInherit | NotInheritable ] [ Partial ] _
Class name [ ( Of typelist ) ]
   [ Inherits classname ]
   [ Implements interfacenames ]
   [ statements ]
End Class

其中：

• attributelist 是应用于类的属性列表。可选。

• accessmodifier 定义类的访问级别，其值包括 - Public、Protected、Friend、Protected Friend 和 Private。可选。

• Shadows 指示变量重新声明并隐藏基类中同名元素或一组重载元素。可选。

• MustInherit 指定该类只能用作基类，并且不能直接从中创建对象，即抽象类。可选。

• NotInheritable 指定该类不能用作基类。

• Partial 指示类的部分定义。

• Inherits 指定它继承的基类。

• Implements 指定类继承的接口。

以下示例演示了一个 Box 类，它具有三个数据成员：length、breadth 和 height：

Module mybox
   Class Box
      Public length As Double   ' Length of a box
      Public breadth As Double  ' Breadth of a box
      Public height As Double   ' Height of a box
   End Class
   Sub Main()
      Dim Box1 As Box = New Box()        ' Declare Box1 of type Box
      Dim Box2 As Box = New Box()        ' Declare Box2 of type Box
      Dim volume As Double = 0.0         ' Store the volume of a box here
      
      ' box 1 specification
      Box1.height = 5.0
      Box1.length = 6.0
      Box1.breadth = 7.0
      
      ' box 2 specification
      Box2.height = 10.0
      Box2.length = 12.0	
      Box2.breadth = 13.0
      
      'volume of box 1
      volume = Box1.height * Box1.length * Box1.breadth
      Console.WriteLine("Volume of Box1 : {0}", volume)
      
      'volume of box 2
      volume = Box2.height * Box2.length * Box2.breadth
      Console.WriteLine("Volume of Box2 : {0}", volume)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Volume of Box1 : 210
Volume of Box2 : 1560

成员函数和封装 (Member Functions and Encapsulation)

类的成员函数是在类定义中定义或原型与其他变量相同的函数。它操作其所属类的任何对象，并可以访问该对象的类的所有成员。

成员变量是对象（从设计角度来看）的属性，它们被设置为私有以实现封装。这些变量只能使用公共成员函数访问。

让我们将上述概念用于设置和获取类中不同类成员的值：

Module mybox
   Class Box
      Public length As Double    ' Length of a box
      Public breadth As Double   ' Breadth of a box
      Public height As Double    ' Height of a box
      Public Sub setLength(ByVal len As Double)
         length = len
      End Sub
      
      Public Sub setBreadth(ByVal bre As Double)
         breadth = bre
      End Sub
      
      Public Sub setHeight(ByVal hei As Double)
         height = hei
      End Sub
      
      Public Function getVolume() As Double
         Return length * breadth * height
      End Function
   End Class
   Sub Main()
      Dim Box1 As Box = New Box()        ' Declare Box1 of type Box
      Dim Box2 As Box = New Box()        ' Declare Box2 of type Box
      Dim volume As Double = 0.0         ' Store the volume of a box here

      ' box 1 specification
      Box1.setLength(6.0)
      Box1.setBreadth(7.0)
      Box1.setHeight(5.0)
      
      'box 2 specification
      Box2.setLength(12.0)
      Box2.setBreadth(13.0)
      Box2.setHeight(10.0)
      
      ' volume of box 1
      volume = Box1.getVolume()
      Console.WriteLine("Volume of Box1 : {0}", volume)

      'volume of box 2
      volume = Box2.getVolume()
      Console.WriteLine("Volume of Box2 : {0}", volume)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Volume of Box1 : 210
Volume of Box2 : 1560

构造函数和析构函数 (Constructors and Destructors)

类的构造函数是类的特殊成员 Sub，每当我们创建该类的新的对象时都会执行。构造函数的名称为New，并且它没有任何返回类型。

以下程序解释了构造函数的概念：

Class Line
   Private length As Double    ' Length of a line
   Public Sub New()   'constructor
      Console.WriteLine("Object is being created")
   End Sub
   
   Public Sub setLength(ByVal len As Double)
      length = len
   End Sub
     
   Public Function getLength() As Double
      Return length
   End Function
   Shared Sub Main()
      Dim line As Line = New Line()
      'set line length
      line.setLength(6.0)
      Console.WriteLine("Length of line : {0}", line.getLength())
      Console.ReadKey()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Object is being created
Length of line : 6

默认构造函数没有任何参数，但如果需要，构造函数可以有参数。这种构造函数称为参数化构造函数。此技术可帮助您在创建对象时为其分配初始值，如下例所示：

Class Line
   Private length As Double    ' Length of a line
   Public Sub New(ByVal len As Double)   'parameterised constructor
      Console.WriteLine("Object is being created, length = {0}", len)
      length = len
   End Sub
   Public Sub setLength(ByVal len As Double)
      length = len
   End Sub
       
   Public Function getLength() As Double
      Return length
   End Function
   Shared Sub Main()
      Dim line As Line = New Line(10.0)
      Console.WriteLine("Length of line set by constructor : {0}", line.getLength())
      'set line length
      line.setLength(6.0)
      Console.WriteLine("Length of line set by setLength : {0}", line.getLength())
      Console.ReadKey()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Object is being created, length = 10
Length of line set by constructor : 10
Length of line set by setLength : 6

析构函数是类的特殊成员 Sub，每当其类的对象超出范围时都会执行。

析构函数的名称为Finalize，它既不能返回值，也不能接受任何参数。析构函数对于在退出程序之前释放资源（如关闭文件、释放内存等）非常有用。

析构函数不能被继承或重载。

以下示例解释了析构函数的概念：

Class Line
   Private length As Double    ' Length of a line
   Public Sub New()   'parameterised constructor
      Console.WriteLine("Object is being created")
   End Sub
   
   Protected Overrides Sub Finalize()  ' destructor
      Console.WriteLine("Object is being deleted")
   End Sub
   
   Public Sub setLength(ByVal len As Double)
      length = len
   End Sub
   
   Public Function getLength() As Double
      Return length
   End Function
   
   Shared Sub Main()
      Dim line As Line = New Line()
      'set line length
      line.setLength(6.0)
      Console.WriteLine("Length of line : {0}", line.getLength())
      Console.ReadKey()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Object is being created
Length of line : 6
Object is being deleted

VB.Net 类的共享成员 (Shared Members of a VB.Net Class)

我们可以使用 Shared 关键字将类成员定义为静态的。当我们将类的成员声明为 Shared 时，这意味着无论创建了多少个类的对象，都只有一个成员副本。

关键字Shared意味着类中只有一个成员实例存在。共享变量用于定义常量，因为可以通过调用类而不创建其实例来检索它们的值。

共享变量可以在成员函数或类定义之外初始化。您也可以在类定义内初始化共享变量。

您还可以将成员函数声明为 Shared。此类函数只能访问共享变量。即使在创建对象之前，共享函数也存在。

以下示例演示了共享成员的使用：

Class StaticVar
   Public Shared num As Integer
   Public Sub count()
      num = num + 1
   End Sub
   Public Shared Function getNum() As Integer
      Return num
   End Function
   Shared Sub Main()
      Dim s As StaticVar = New StaticVar()
      s.count()
      s.count()
      s.count()
      Console.WriteLine("Value of variable num: {0}", StaticVar.getNum())
      Console.ReadKey()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Value of variable num: 3

继承 (Inheritance)

面向对象编程中最重要概念之一是继承。继承允许我们根据另一个类定义一个类，这使得创建和维护应用程序更容易。这也提供了重用代码功能和加快实现时间的机会。

创建类时，程序员可以指定新类应该继承现有类的成员，而不是编写全新的数据成员和成员函数。这个现有类称为基类，新类称为派生类。

基类和派生类 (Base & Derived Classes)

一个类可以从多个类或接口派生，这意味着它可以继承多个基类或接口的数据和函数。

VB.Net 中用于创建派生类的语法如下：

<access-specifier> Class <base_class>
...
End Class
Class <derived_class>: Inherits <base_class>
...
End Class

考虑一个基类 Shape 及其派生类 Rectangle：

' Base class
Class Shape
   Protected width As Integer
   Protected height As Integer
   Public Sub setWidth(ByVal w As Integer)
      width = w
   End Sub
   Public Sub setHeight(ByVal h As Integer)
      height = h
   End Sub
End Class
' Derived class
Class Rectangle : Inherits Shape
   Public Function getArea() As Integer
      Return (width * height)
   End Function
End Class
Class RectangleTester
   Shared Sub Main()
      Dim rect As Rectangle = New Rectangle()
      rect.setWidth(5)
      rect.setHeight(7)
      ' Print the area of the object.
      Console.WriteLine("Total area: {0}", rect.getArea())
      Console.ReadKey()
   End Sub	
End Class

当上述代码编译并执行时，它会产生以下结果：

Total area: 35

基类初始化 (Base Class Initialization)

派生类继承基类的成员变量和成员方法。因此，在创建子类之前，应先创建超类对象。超类或基类在 VB.Net 中隐式称为MyBase

以下程序演示了这一点：

' Base class
Class Rectangle
   Protected width As Double
   Protected length As Double
   Public Sub New(ByVal l As Double, ByVal w As Double)
      length = l
      width = w
   End Sub
   Public Function GetArea() As Double
      Return (width * length)
   End Function
   Public Overridable Sub Display()
      Console.WriteLine("Length: {0}", length)
      Console.WriteLine("Width: {0}", width)
      Console.WriteLine("Area: {0}", GetArea())
   End Sub
   'end class Rectangle  
End Class

'Derived class
Class Tabletop : Inherits Rectangle
   Private cost As Double
   Public Sub New(ByVal l As Double, ByVal w As Double)
      MyBase.New(l, w)
   End Sub
   Public Function GetCost() As Double
      Dim cost As Double
      cost = GetArea() * 70
      Return cost
   End Function
   Public Overrides Sub Display()
      MyBase.Display()
      Console.WriteLine("Cost: {0}", GetCost())
   End Sub
    'end class Tabletop
End Class
Class RectangleTester
   Shared Sub Main()
      Dim t As Tabletop = New Tabletop(4.5, 7.5)
      t.Display()
      Console.ReadKey()
   End Sub
End Class

当上述代码编译并执行时，它会产生以下结果：

Length: 4.5
Width: 7.5
Area: 33.75
Cost: 2362.5

VB.Net 支持多重继承。

VB.Net - 异常处理

异常是在程序执行期间出现的问题。异常是对程序运行期间出现的异常情况的响应，例如尝试除以零。

异常提供了一种将控制从程序的一部分转移到另一部分的方法。VB.Net 异常处理基于四个关键字 - Try、Catch、Finally 和 Throw。

• Try − Try 块标识将为其激活特定异常的代码块。它后面跟着一个或多个 Catch 块。

• 捕获 (Catch) − 程序使用异常处理程序在程序中需要处理问题的地方捕获异常。Catch 关键字表示捕获异常。

• 最终 (Finally) − Finally 块用于执行给定的语句集，无论是否抛出异常。例如，如果打开了一个文件，无论是否引发异常，都必须关闭它。

• 抛出 (Throw) − 当出现问题时，程序会抛出异常。这是使用 Throw 关键字完成的。

语法

假设一个代码块会引发异常，方法使用 Try 和 Catch 关键字的组合来捕获异常。Try/Catch 块放置在可能生成异常的代码周围。Try/Catch 块内的代码称为受保护代码，使用 Try/Catch 的语法如下所示：

Try
   [ tryStatements ]
   [ Exit Try ]
[ Catch [ exception [ As type ] ] [ When expression ]
   [ catchStatements ]
   [ Exit Try ] ]
[ Catch ... ]
[ Finally
   [ finallyStatements ] ]
End Try

如果 try 块在不同情况下引发多个异常，可以列出多个 catch 语句来捕获不同类型的异常。

.Net Framework 中的异常类

在 .Net Framework 中，异常由类表示。.Net Framework 中的异常类主要直接或间接地派生自 System.Exception 类。一些从 System.Exception 类派生的异常类是 System.ApplicationException 和 System.SystemException 类。

System.ApplicationException 类支持应用程序程序生成的异常。因此，程序员定义的异常应该从此类派生。

System.SystemException 类是所有预定义系统异常的基类。

下表提供了一些从 Sytem.SystemException 类派生的预定义异常类：

处理异常

VB.Net 提供了一种结构化的解决方案来处理 try 和 catch 块中的异常处理问题。使用这些块，核心程序语句与错误处理语句分开。

这些错误处理块使用 Try、Catch 和 Finally 关键字实现。以下是在发生被零除情况时抛出异常的示例：

Module exceptionProg
   Sub division(ByVal num1 As Integer, ByVal num2 As Integer)
      Dim result As Integer
      Try
         result = num1 \ num2
      Catch e As DivideByZeroException
         Console.WriteLine("Exception caught: {0}", e)
      Finally
         Console.WriteLine("Result: {0}", result)
      End Try
   End Sub
   Sub Main()
      division(25, 0)
      Console.ReadKey()
  End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Exception caught: System.DivideByZeroException: Attempted to divide by zero. 
at ...
Result: 0

创建用户定义的异常

您还可以定义自己的异常。用户定义的异常类派生自 ApplicationException 类。以下示例演示了这一点：

Module exceptionProg
   Public Class TempIsZeroException : Inherits ApplicationException
      Public Sub New(ByVal message As String)
         MyBase.New(message)
      End Sub
   End Class
   Public Class Temperature
      Dim temperature As Integer = 0
      Sub showTemp()
         If (temperature = 0) Then
            Throw (New TempIsZeroException("Zero Temperature found"))
         Else
            Console.WriteLine("Temperature: {0}", temperature)
         End If
      End Sub
   End Class
   Sub Main()
      Dim temp As Temperature = New Temperature()
      Try
         temp.showTemp()
      Catch e As TempIsZeroException
         Console.WriteLine("TempIsZeroException: {0}", e.Message)
      End Try
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

TempIsZeroException: Zero Temperature found

抛出对象

如果对象直接或间接地派生自 System.Exception 类，则可以抛出该对象。

您可以在 catch 块中使用 throw 语句抛出当前对象，如下所示：

Throw [ expression ]

以下程序演示了这一点：

Module exceptionProg
   Sub Main()
      Try
         Throw New ApplicationException("A custom exception _ is being thrown here...")
      Catch e As Exception
         Console.WriteLine(e.Message)
      Finally
         Console.WriteLine("Now inside the Finally Block")
      End Try
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

A custom exception is being thrown here...
Now inside the Finally Block

VB.Net - 文件处理

文件是在磁盘上存储的数据集合，具有特定的名称和目录路径。当文件打开以进行读取或写入时，它就变成了流。

流基本上是通过通信路径传递的字节序列。主要有两个流：输入流和输出流。输入流用于从文件读取数据（读取操作），输出流用于写入文件（写入操作）。

VB.Net I/O 类

System.IO 命名空间具有用于执行各种文件操作的各种类，例如创建和删除文件、读取或写入文件、关闭文件等。

下表显示了 System.IO 命名空间中一些常用的非抽象类：

FileStream 类

System.IO 命名空间中的 FileStream 类有助于读取、写入和关闭文件。此类派生自抽象类 Stream。

需要创建一个 FileStream 对象来创建新文件或打开现有文件。创建 FileStream 对象的语法如下：

Dim <object_name> As FileStream = New FileStream(<file_name>, <FileMode Enumerator>, <FileAccess Enumerator>, <FileShare Enumerator>)

例如，要为读取名为 sample.txt 的文件创建 FileStream 对象 F：

Dim f1 As FileStream = New FileStream("sample.txt", FileMode.OpenOrCreate, FileAccess.ReadWrite)

示例

以下程序演示了 FileStream 类的用法：

Imports System.IO
Module fileProg
   Sub Main()
      Dim f1 As FileStream = New FileStream("sample.txt", _ FileMode.OpenOrCreate, FileAccess.ReadWrite)
      Dim i As Integer
      
      For i = 0 To 20
         f1.WriteByte(CByte(i))
      Next i
      f1.Position = 0
      
      For i = 0 To 20
         Console.Write("{0} ", f1.ReadByte())
      Next i
      f1.Close()
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 -1

VB.Net 中的高级文件操作

前面的示例提供了 VB.Net 中简单的文件操作。但是，要利用 System.IO 类的强大功能，需要了解这些类的常用属性和方法。

我们将在以下部分讨论这些类及其执行的操作。请单击提供的链接以访问各个部分：

VB.Net - 基本控件

对象是在 Visual Basic 窗体上使用工具箱控件创建的一种用户界面元素类型。事实上，在 Visual Basic 中，窗体本身就是一个对象。每个 Visual Basic 控件都包含三个重要元素：

• 属性描述对象；

• 方法使对象执行某些操作；以及

• 事件是对象执行某些操作时发生的事情。

控件属性

所有 Visual Basic 对象都可以通过设置其属性来移动、调整大小或自定义。属性是 Visual Basic 对象持有的值或特性，例如标题或前景色。

属性可以在设计时使用属性窗口设置，也可以在运行时使用程序代码中的语句设置。

Object. Property = Value

其中

• 对象是您要自定义的对象的名称。

• 属性是您要更改的特性。

• 值是新的属性设置。

例如：

Form1.Caption = "Hello"

您可以使用属性窗口设置任何窗体属性。大多数属性可以在应用程序执行期间设置或读取。您可以参考 Microsoft 文档，了解与不同控件关联的完整属性列表及其应用的限制。

控件方法

方法是作为类的成员创建的过程，它们使对象执行某些操作。方法用于访问或操作对象的特性或变量。在类中将使用的主要有两类方法：

• 如果您使用的是控件（例如工具箱提供的控件之一），则可以调用其任何公共方法。此类方法的要求取决于所使用的类。

• 如果现有方法无法执行您所需的任务，则可以向类添加方法。

例如，MessageBox 控件有一个名为 Show 的方法，它在下面的代码片段中调用：

Public Class Form1
   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) 
   Handles Button1.Click
      MessageBox.Show("Hello, World")
   End Sub
End Class

控件事件

事件是一种信号，它通知应用程序已发生重要事件。例如，当用户单击窗体上的控件时，窗体可以引发 Click 事件并调用处理该事件的过程。与窗体关联的事件类型多种多样，例如单击、双击、关闭、加载、调整大小等。

以下是窗体 Load 事件处理程序子例程的默认结构。您可以双击代码查看此代码，这将为您提供与窗体控件关联的所有事件的完整列表：

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
   'event handler code goes here
End Sub

此处，Handles MyBase.Load 表示 Form1_Load() 子例程处理 Load 事件。类似地，您可以检查单击、双击的存根代码。如果要初始化某些变量（如属性等），则会将此类代码保留在 Form1_Load() 子例程中。此处需要注意的重要一点是事件处理程序的名称，默认情况下为 Form1_Load，但您可以根据应用程序编程中使用的命名约定更改此名称。

基本控件

VB.Net 提供了各种控件，可帮助您创建丰富的用户界面。所有这些控件的功能都在相应的控件类中定义。控件类在 System.Windows.Forms 命名空间中定义。

下表列出了一些常用的控件：

VB.Net - 对话框

Windows 窗体中有很多内置的对话框可用于各种任务，例如打开和保存文件、打印页面、为应用程序用户提供颜色、字体、页面设置等的选项。这些内置对话框减少了开发人员的时间和工作量。

所有这些对话框控件类都继承自CommonDialog类，并覆盖基类的RunDialog()函数以创建特定的对话框。

当对话框用户调用其ShowDialog()函数时，会自动调用RunDialog()函数。

ShowDialog 方法用于在运行时显示所有对话框控件。它返回DialogResult枚举类型的值。DialogResult 枚举的值为：

• Abort − 当用户单击“Abort”按钮时，返回 DialogResult.Abort 值。

• Cancel − 当用户单击“Cancel”按钮时，返回 DialogResult.Cancel 值。

• Ignore − 当用户单击“Ignore”按钮时，返回 DialogResult.Ignore 值。

• No − 当用户单击“No”按钮时，返回 DialogResult.No 值。

• None − 不返回任何值，对话框继续运行。

• OK − 当用户单击“OK”按钮时，返回 DialogResult.OK 值。

• Retry − 当用户单击“Retry”按钮时，返回 DialogResult.Retry 值。

• Yes − 当用户单击“Yes”按钮时，返回 DialogResult.Yes 值。

下图显示了公共对话框类的继承关系：

所有上述类在设计时都具有相应的控件，可以从工具箱中添加。您可以通过以编程方式实例化类或使用相关控件来将这些类的相关功能包含到您的应用程序中。

双击工具箱中的任何对话框控件或将控件拖放到窗体上时，它会显示在 Windows 窗体设计器底部的组件托盘中，它们不会直接显示在窗体上。

下表列出了常用的对话框控件。单击以下链接查看其详细信息：

VB.Net - 高级窗体

在本章中，我们将学习以下概念：

• 在应用程序中添加菜单和子菜单

• 在窗体中添加剪切、复制和粘贴功能

• 在窗体中锚定和停靠控件

• 模式窗体

在应用程序中添加菜单和子菜单

传统上，Menu、MainMenu、ContextMenu 和 MenuItem 类用于在 Windows 应用程序中添加菜单、子菜单和上下文菜单。

现在，MenuStrip、ToolStripMenuItem、ToolStripDropDown 和 ToolStripDropDownMenu 控件取代了以前版本的与菜单相关的控件，并为其添加了功能。但是，为了向后兼容性和将来的使用，旧的控件类仍然保留。

让我们首先使用旧版本的控件创建一个典型的 Windows 主菜单栏和子菜单，因为这些控件在旧应用程序中仍然被广泛使用。

以下是一个示例，它展示了如何创建带有菜单项的菜单栏：文件、编辑、查看和项目。文件菜单具有子菜单新建、打开和保存。

双击窗体，并将以下代码放入打开的窗口中。

Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      'defining the main menu bar
      Dim mnuBar As New MainMenu()
      'defining the menu items for the main menu bar
      Dim myMenuItemFile As New MenuItem("&File")
      Dim myMenuItemEdit As New MenuItem("&Edit")
      Dim myMenuItemView As New MenuItem("&View")
      Dim myMenuItemProject As New MenuItem("&Project")

      'adding the menu items to the main menu bar
      mnuBar.MenuItems.Add(myMenuItemFile)
      mnuBar.MenuItems.Add(myMenuItemEdit)
      mnuBar.MenuItems.Add(myMenuItemView)
      mnuBar.MenuItems.Add(myMenuItemProject)

     ' defining some sub menus
      Dim myMenuItemNew As New MenuItem("&New")
      Dim myMenuItemOpen As New MenuItem("&Open")
      Dim myMenuItemSave As New MenuItem("&Save")

      'add sub menus to the File menu
      myMenuItemFile.MenuItems.Add(myMenuItemNew)
      myMenuItemFile.MenuItems.Add(myMenuItemOpen)
      myMenuItemFile.MenuItems.Add(myMenuItemSave)

      'add the main menu to the form
      Me.Menu = mnuBar
     
      ' Set the caption bar text of the form.  
      Me.Text = "tutorialspoint.com"
   End Sub
End Class

当使用 Microsoft Visual Studio 工具栏上的“启动”按钮执行和运行上述代码时，它将显示以下窗口：

Windows 窗体包含一组丰富的类，用于创建具有现代外观、外观和感觉的自定义菜单。MenuStrip、ToolStripMenuItem、ContextMenuStrip 控件用于高效地创建菜单栏和上下文菜单。

单击以下链接查看其详细信息：

在窗体中添加剪切、复制和粘贴功能

ClipBoard 类公开的方法用于在应用程序中添加剪切、复制和粘贴功能。ClipBoard 类提供将数据放置到系统剪贴板以及从系统剪贴板检索数据的方法。

它具有以下常用方法：

以下是一个示例，它展示了如何使用 Clipboard 类的方 法剪切、复制和粘贴数据。请按照以下步骤操作：

• 在窗体上添加一个富文本框控件和三个按钮控件。

• 将按钮的 Text 属性分别更改为“剪切”、“复制”和“粘贴”。

• 双击按钮，将以下代码添加到代码编辑器中：

Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) _ 
    Handles MyBase.Load
      ' Set the caption bar text of the form.  
      Me.Text = "tutorialspoint.com"
   End Sub
   
   Private Sub Button1_Click(sender As Object, e As EventArgs) _ 
      Handles Button1.Click
      Clipboard.SetDataObject(RichTextBox1.SelectedText)
      RichTextBox1.SelectedText = ""
   End Sub
   
   Private Sub Button2_Click(sender As Object, e As EventArgs) _
       Handles Button2.Click
      Clipboard.SetDataObject(RichTextBox1.SelectedText)
   End Sub
   
   Private Sub Button3_Click(sender As Object, e As EventArgs) _
    Handles Button3.Click
      Dim iData As IDataObject
      iData = Clipboard.GetDataObject()
      If (iData.GetDataPresent(DataFormats.Text)) Then
         RichTextBox1.SelectedText = iData.GetData(DataFormats.Text)
      Else
         RichTextBox1.SelectedText = " "
      End If
   End Sub
End Class

当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

输入一些文本并检查按钮如何工作。

在窗体中锚定和停靠控件

锚定允许您为控件设置一个锚定位置到其容器控件（例如窗体）的边缘。Control 类的Anchor 属性允许您设置此属性的值。Anchor 属性获取或设置控件绑定的容器的边缘，并确定控件如何与其父级一起调整大小。

当您将控件锚定到窗体时，当窗体调整大小时，控件会保持与窗体边缘的距离及其锚定位置。

您可以从“属性”窗口设置控件的 Anchor 属性值：

例如，让我们在窗体上添加一个 Button 控件，并将其 Anchor 属性设置为 Bottom、Right。运行此窗体以查看 Button 控件相对于窗体的原始位置。

现在，当您拉伸窗体时，Button 与窗体右下角之间的距离保持不变。

控件的停靠意味着将其停靠到其容器的某个边缘。在停靠中，控件完全填充容器的某个区域。

Control 类的Dock 属性执行此操作。Dock 属性获取或设置停靠到其父控件的哪些控件边框，并确定控件如何与其父级一起调整大小。

您可以从“属性”窗口设置控件的 Dock 属性值：

例如，让我们在窗体上添加一个 Button 控件，并将其 Dock 属性设置为 Bottom。运行此窗体以查看 Button 控件相对于窗体的原始位置。

现在，当您拉伸窗体时，Button 会随着窗体调整自身大小。

模式窗体

模式窗体是指在继续处理应用程序的其余部分之前需要关闭或隐藏的窗体。所有对话框都是模式窗体。消息框也是模式窗体。

您可以通过两种方式调用模式窗体：

• 调用ShowDialog 方法

• 调用Show 方法

让我们来看一个示例，在这个示例中，我们将创建一个模式窗体（对话框）。请按照以下步骤操作：

• 向应用程序添加一个窗体 Form1，并向 Form1 添加两个标签和一个按钮控件。

• 将第一个标签和按钮的文本属性分别更改为“欢迎使用 Tutorials Point”和“输入您的姓名”。保持第二个标签的文本属性为空。

  

• 添加一个新的 Windows 窗体 Form2，并在 Form2 中添加两个按钮、一个标签和一个文本框。

• 将按钮的文本属性分别更改为“确定”和“取消”。将标签的文本属性更改为“输入您的姓名：”。

• 将 Form2 的FormBorderStyle 属性设置为FixedDialog，使其具有对话框边框。

• 将 Form2 的ControlBox 属性设置为 False。

• 将 Form2 的ShowInTaskbar 属性设置为 False。

• 将“确定”按钮的DialogResult 属性设置为 OK，将“取消”按钮的DialogResult 属性设置为 Cancel。

在 Form2 的 Form2_Load 方法中添加以下代码片段：

Private Sub Form2_Load(sender As Object, e As EventArgs) _
   Handles MyBase.Load
   AcceptButton = Button1
   CancelButton = Button2
End Sub

在 Form1 的 Button1_Click 方法中添加以下代码片段：

Private Sub Button1_Click(sender As Object, e As EventArgs) _
   Handles Button1.Click
   Dim frmSecond As Form2 = New Form2()
   
   If frmSecond.ShowDialog() = DialogResult.OK Then
      Label2.Text = frmSecond.TextBox1.Text
   End If
End Sub

当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

单击“输入您的姓名”按钮将显示第二个窗体。

单击“确定”按钮将控制权和信息从模态窗体返回到上一个窗体。

VB.Net - 事件处理

事件基本上是用户操作，例如按键、单击、鼠标移动等，或某些事件，例如系统生成的通知。应用程序需要在事件发生时做出响应。

单击按钮、在文本框中输入一些文本或单击菜单项，这些都是事件的示例。事件是一个调用函数或可能导致另一个事件的动作。事件处理程序是指示如何响应事件的函数。

VB.Net 是一种事件驱动的语言。主要有两种类型的事件：

• 鼠标事件

• 键盘事件

处理鼠标事件

鼠标事件在窗体和控件中的鼠标移动时发生。以下是与 Control 类相关的各种鼠标事件：

• MouseDown - 当按下鼠标按钮时发生

• MouseEnter - 当鼠标指针进入控件时发生

• MouseHover - 当鼠标指针悬停在控件上时发生

• MouseLeave - 当鼠标指针离开控件时发生

• MouseMove - 当鼠标指针在控件上移动时发生

• MouseUp - 当鼠标指针在控件上并且释放鼠标按钮时发生

• MouseWheel - 当鼠标滚轮移动且控件具有焦点时发生

鼠标事件的事件处理程序获取类型为MouseEventArgs 的参数。MouseEventArgs 对象用于处理鼠标事件。它具有以下属性：

• Buttons - 指示按下的鼠标按钮

• Clicks - 指示单击次数

• Delta - 指示鼠标滚轮旋转的微调次数

• X - 指示鼠标单击的 x 坐标

• Y - 指示鼠标单击的 y 坐标

示例

以下是一个示例，它显示了如何处理鼠标事件。请按照以下步骤操作：

• 在窗体中添加三个标签、三个文本框和一个按钮控件。

• 将标签的文本属性分别更改为 - 客户 ID、姓名和地址。

• 将文本框的名称属性分别更改为 txtID、txtName 和 txtAddress。

• 将按钮的文本属性更改为“提交”。

• 在代码编辑器窗口中添加以下代码：

Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspont.com"
   End Sub

   Private Sub txtID_MouseEnter(sender As Object, e As EventArgs)_
      Handles txtID.MouseEnter
      'code for handling mouse enter on ID textbox
      txtID.BackColor = Color.CornflowerBlue
      txtID.ForeColor = Color.White
   End Sub
   
   Private Sub txtID_MouseLeave(sender As Object, e As EventArgs) _
      Handles txtID.MouseLeave
      'code for handling mouse leave on ID textbox
      txtID.BackColor = Color.White
      txtID.ForeColor = Color.Blue
   End Sub
   
   Private Sub txtName_MouseEnter(sender As Object, e As EventArgs) _
      Handles txtName.MouseEnter
      'code for handling mouse enter on Name textbox
      txtName.BackColor = Color.CornflowerBlue
      txtName.ForeColor = Color.White
   End Sub
   
   Private Sub txtName_MouseLeave(sender As Object, e As EventArgs) _
      Handles txtName.MouseLeave
      'code for handling mouse leave on Name textbox
      txtName.BackColor = Color.White
      txtName.ForeColor = Color.Blue
   End Sub
   
   Private Sub txtAddress_MouseEnter(sender As Object, e As EventArgs) _
      Handles txtAddress.MouseEnter
      'code for handling mouse enter on Address textbox
      txtAddress.BackColor = Color.CornflowerBlue
      txtAddress.ForeColor = Color.White
   End Sub
   
   Private Sub txtAddress_MouseLeave(sender As Object, e As EventArgs) _
      Handles txtAddress.MouseLeave
      'code for handling mouse leave on Address textbox
      txtAddress.BackColor = Color.White
      txtAddress.ForeColor = Color.Blue
   End Sub

   Private Sub Button1_Click(sender As Object, e As EventArgs) _
      Handles Button1.Click
      MsgBox("Thank you " & txtName.Text & ", for your kind cooperation")
   End Sub
End Class

当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

尝试在文本框中输入文本并检查鼠标事件：

处理键盘事件

以下是与 Control 类相关的各种键盘事件：

• KeyDown - 当按下按键且控件具有焦点时发生

• KeyPress - 当按下按键且控件具有焦点时发生

• KeyUp - 当释放按键且控件具有焦点时发生

KeyDown 和 KeyUp 事件的事件处理程序获取类型为KeyEventArgs 的参数。此对象具有以下属性：

• Alt - 指示是否按下了 ALT 键

• Control - 指示是否按下了 CTRL 键

• Handled - 指示是否处理了事件

• KeyCode - 存储事件的键盘代码

• KeyData - 存储事件的键盘数据

• KeyValue - 存储事件的键盘值

• Modifiers - 指示按下了哪些修饰键（Ctrl、Shift 和/或 Alt）

• Shift - 指示是否按下了 Shift 键

KeyDown 和 KeyUp 事件的事件处理程序获取类型为KeyEventArgs 的参数。此对象具有以下属性：

• Handled - 指示是否处理了 KeyPress 事件

• KeyChar - 存储与按下的键相对应的字符

示例

让我们继续使用前面的示例来演示如何处理键盘事件。代码将验证用户是否为其客户 ID 和年龄输入了一些数字。

• 添加一个文本属性为“年龄”的标签，并添加一个名为 txtAge 的相应文本框。

• 添加以下代码以处理 txtID 文本框的 KeyUP 事件。

Private Sub txtID_KeyUP(sender As Object, e As KeyEventArgs) _
   Handles txtID.KeyUp
   
   If (Not Char.IsNumber(ChrW(e.KeyCode))) Then
      MessageBox.Show("Enter numbers for your Customer ID")
      txtID.Text = " "
   End If
End Sub

• 添加以下代码以处理 txtID 文本框的 KeyUP 事件。

Private Sub txtAge_KeyUP(sender As Object, e As KeyEventArgs) _
   Handles txtAge.KeyUp
   
   If (Not Char.IsNumber(ChrW(e.keyCode))) Then
      MessageBox.Show("Enter numbers for age")
      txtAge.Text = " "
   End If
End Sub

当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

如果您将年龄或 ID 的文本留空或输入一些非数字数据，它会显示一个警告消息框并清除相应的文本：

VB.Net - 正则表达式

正则表达式是一种可以与输入文本匹配的模式。.Net 框架提供了一个允许这种匹配的正则表达式引擎。模式由一个或多个字符字面量、运算符或构造组成。

定义正则表达式的构造

有各种类型的字符、运算符和构造可以让你定义正则表达式。单击以下链接以查找这些构造。

• 字符转义

• 字符类

• 锚点

• 分组构造

• 量词

• 反向引用构造

• 替换构造

• 替换

• 其他构造

Regex 类

Regex 类用于表示正则表达式。

Regex 类具有以下常用方法：

有关方法和属性的完整列表，请参阅 Microsoft 文档。

示例 1

以下示例匹配以“S”开头的单词：

Imports System.Text.RegularExpressions
Module regexProg
   Sub showMatch(ByVal text As String, ByVal expr As String)
      Console.WriteLine("The Expression: " + expr)
      Dim mc As MatchCollection = Regex.Matches(text, expr)
      Dim m As Match
      
      For Each m In mc
         Console.WriteLine(m)
      Next m
   End Sub
   
   Sub Main()
      Dim str As String = "A Thousand Splendid Suns"
      Console.WriteLine("Matching words that start with 'S': ")
      showMatch(str, "\bS\S*")
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Matching words that start with 'S':
The Expression: \bS\S*
Splendid
Suns

示例 2

以下示例匹配以“m”开头并以“e”结尾的单词：

Imports System.Text.RegularExpressions
Module regexProg
   Sub showMatch(ByVal text As String, ByVal expr As String)
      Console.WriteLine("The Expression: " + expr)
      Dim mc As MatchCollection = Regex.Matches(text, expr)
      Dim m As Match
      
      For Each m In mc
         Console.WriteLine(m)
      Next m
   End Sub
   
   Sub Main()
      Dim str As String = "make a maze and manage to measure it"
      Console.WriteLine("Matching words that start with 'm' and ends with 'e': ")
      showMatch(str, "\bm\S*e\b")
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Matching words start with 'm' and ends with 'e':
The Expression: \bm\S*e\b
make
maze
manage
measure

示例 3

此示例替换多余的空格：

Imports System.Text.RegularExpressions
Module regexProg
   Sub Main()
      Dim input As String = "Hello    World   "
      Dim pattern As String = "\\s+"
      Dim replacement As String = " "
      Dim rgx As Regex = New Regex(pattern)
      Dim result As String = rgx.Replace(input, replacement)
      
      Console.WriteLine("Original String: {0}", input)
      Console.WriteLine("Replacement String: {0}", result)
      Console.ReadKey()
   End Sub
End Module

当上述代码编译并执行时，它会产生以下结果：

Original String: Hello   World   
Replacement String: Hello World   

VB.Net - 数据库访问

应用程序首先与数据库通信以检索其中存储的数据并以用户友好的方式呈现它，其次是通过插入、修改和删除数据来更新数据库。

Microsoft ActiveX Data Objects.Net (ADO.Net) 是 .Net 框架的一部分，.Net 应用程序使用它来检索、访问和更新数据。

ADO.Net 对象模型

ADO.Net 对象模型只不过是通过各种组件的结构化流程。对象模型可以图解如下：

驻留在数据存储或数据库中的数据通过数据提供程序检索。数据提供程序的各种组件为应用程序检索数据并更新数据。

应用程序可以通过数据集或数据读取器访问数据。

• 数据集将数据存储在断开连接的缓存中，应用程序从中检索数据。

• 数据读取器以只读和向前模式为应用程序提供数据。

数据提供程序

数据提供程序用于连接到数据库、执行命令和检索数据、将其存储在数据集中、读取检索到的数据和更新数据库。

ADO.Net 中的数据提供程序包含以下四个对象：

ADO.Net 中包含以下不同类型的数据提供程序

• 用于 SQL Server 的 .Net Framework 数据提供程序 - 提供对 Microsoft SQL Server 的访问。

• 用于 OLE DB 的 .Net Framework 数据提供程序 - 提供对使用 OLE DB 公开的数据库的访问。

• 用于 ODBC 的 .Net Framework 数据提供程序 - 提供对 ODBC 公开的数据库的访问。

• 用于 Oracle 的 .Net Framework 数据提供程序 - 提供对 Oracle 数据源的访问。

• EntityClient 提供程序 - 能够通过实体数据模型 (EDM) 应用程序访问数据。

数据集

数据集是数据的内存中表示。它是从数据库检索到的断开连接的缓存记录集。当与数据库建立连接时，数据适配器将创建一个数据集并将数据存储在其中。检索并存储在数据集中后，与数据库的连接将关闭。这称为“断开连接体系结构”。数据集充当包含表、行和列的虚拟数据库。

下图显示了数据集对象模型：

DataSet 类位于System.Data命名空间中。下表描述了 DataSet 的所有组件：

连接到数据库

.Net Framework 提供两种类型的连接类：

• SqlConnection - 用于连接到 Microsoft SQL Server。

• OleDbConnection - 用于连接到各种数据库，例如 Microsoft Access 和 Oracle。

示例 1

我们在名为 testDB 的数据库中有一个存储在 Microsoft SQL Server 中的名为 Customers 的表。请参阅“SQL Server”教程，了解如何在 SQL Server 中创建数据库和数据库表。

让我们连接到此数据库。请按照以下步骤操作：

• 选择工具 → 连接到数据库

• 在“添加连接”对话框中选择服务器名称和数据库名称。

  M

• 单击“测试连接”按钮以检查连接是否成功。

• 在窗体上添加一个 DataGridView。

• 单击“选择数据源”组合框。

• 单击“添加项目数据源”链接。

• 这将打开数据源配置向导。

• 选择数据库作为数据源类型

• 选择 DataSet 作为数据库模型。

• 选择已设置的连接。

• 保存连接字符串。

• 选择数据库对象（在我们的示例中为 Customers 表），然后单击“完成”按钮。

• 选择“预览数据”链接以查看结果网格中的数据：

使用 Microsoft Visual Studio 工具栏中的启动按钮运行应用程序时，将显示以下窗口：

示例 2

在此示例中，让我们使用代码访问 DataGridView 控件中的数据。请按照以下步骤操作：

• 在窗体中添加 DataGridView 控件和一个按钮。

• 将按钮控件的文本更改为“填充”。

• 双击按钮控件以添加按钮 Click 事件所需的代码，如下所示：

Imports System.Data.SqlClient
Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) _
   Handles MyBase.Load
      'TODO: This line of code loads data into the 'TestDBDataSet.CUSTOMERS' table.   
      You can move, or remove it, as needed.
      
      Me.CUSTOMERSTableAdapter.Fill(Me.TestDBDataSet.CUSTOMERS)
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspoint.com"
   End Sub
   
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      Dim connection As SqlConnection = New sqlconnection()
      connection.ConnectionString = "Data Source=KABIR-DESKTOP; _
         Initial Catalog=testDB;Integrated Security=True"
      connection.Open()
      Dim adp As SqlDataAdapter = New SqlDataAdapter _
      ("select * from Customers", connection)
      Dim ds As DataSet = New DataSet()
      adp.Fill(ds)
      DataGridView1.DataSource = ds.Tables(0)
   End Sub
End Class

• 当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

• 单击“填充”按钮会在数据网格视图控件上显示表格：

创建表、列和行

我们已经讨论过，DataSet 组件（如 DataTable、DataColumn 和 DataRow）分别允许我们创建表、列和行。

以下示例演示了这个概念：

示例 3

到目前为止，我们使用的表和数据库已存在于我们的计算机中。在此示例中，我们将创建一个表，添加列、行和数据，并使用 DataGridView 对象显示该表。

请按照以下步骤操作：

• 在窗体中添加 DataGridView 控件和一个按钮。

• 将按钮控件的文本更改为“填充”。

• 在代码编辑器中添加以下代码。

Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspont.com"
   End Sub
   
   Private Function CreateDataSet() As DataSet
      'creating a DataSet object for tables
      Dim dataset As DataSet = New DataSet()
      ' creating the student table
      Dim Students As DataTable = CreateStudentTable()
      dataset.Tables.Add(Students)
      Return dataset
   End Function
   
   Private Function CreateStudentTable() As DataTable
      Dim Students As DataTable
      Students = New DataTable("Student")
      ' adding columns
      AddNewColumn(Students, "System.Int32", "StudentID")
      AddNewColumn(Students, "System.String", "StudentName")
      AddNewColumn(Students, "System.String", "StudentCity")
      ' adding rows
      AddNewRow(Students, 1, "Zara Ali", "Kolkata")
      AddNewRow(Students, 2, "Shreya Sharma", "Delhi")
      AddNewRow(Students, 3, "Rini Mukherjee", "Hyderabad")
      AddNewRow(Students, 4, "Sunil Dubey", "Bikaner")
      AddNewRow(Students, 5, "Rajat Mishra", "Patna")
      Return Students
   End Function
   
   Private Sub AddNewColumn(ByRef table As DataTable, _ 
   ByVal columnType As String, ByVal columnName As String)
      Dim column As DataColumn = _ 
         table.Columns.Add(columnName, Type.GetType(columnType))
   End Sub

   'adding data into the table
   Private Sub AddNewRow(ByRef table As DataTable, ByRef id As Integer,_
   ByRef name As String, ByRef city As String)
      Dim newrow As DataRow = table.NewRow()
      newrow("StudentID") = id
      newrow("StudentName") = name
      newrow("StudentCity") = city
      table.Rows.Add(newrow)
   End Sub
   
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      Dim ds As New DataSet
      ds = CreateDataSet()
      DataGridView1.DataSource = ds.Tables("Student")
   End Sub
End Class

• 当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

• 单击“填充”按钮会在数据网格视图控件上显示表格：

VB.Net - Excel表格

VB.Net 支持 Microsoft Excel 2010 的 COM 对象模型与您的应用程序之间的互操作性。

为了在您的应用程序中使用此互操作性，您需要在 Windows 窗体应用程序中导入命名空间Microsoft.Office.Interop.Excel。

从 VB.Net 创建 Excel 应用程序

让我们按照 Microsoft Visual Studio 中的以下步骤创建一个 Windows 窗体应用程序：文件 → 新建项目 → Windows 窗体应用程序

最后，选择“确定”，Microsoft Visual Studio 将创建您的项目并显示以下Form1。

在窗体中插入一个 Button 控件 Button1。

将对 Microsoft Excel 对象库的引用添加到您的项目。为此：

• 从“项目”菜单中选择“添加引用”。

• 在“COM”选项卡上，找到 Microsoft Excel 对象库，然后单击“选择”。

• 单击“确定”。

双击代码窗口并填充 Button1 的 Click 事件，如下所示。

'  Add the following code snippet on top of Form1.vb
Imports Excel = Microsoft.Office.Interop.Excel
Public Class Form1
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      Dim appXL As Excel.Application
      Dim wbXl As Excel.Workbook
      Dim shXL As Excel.Worksheet
      Dim raXL As Excel.Range
      
      ' Start Excel and get Application object.
      appXL = CreateObject("Excel.Application")
      appXL.Visible = True
      
      ' Add a new workbook.
      wbXl = appXL.Workbooks.Add
      shXL = wbXl.ActiveSheet
      
      ' Add table headers going cell by cell.
      shXL.Cells(1, 1).Value = "First Name"
      shXL.Cells(1, 2).Value = "Last Name"
      shXL.Cells(1, 3).Value = "Full Name"
      shXL.Cells(1, 4).Value = "Specialization"
      
      ' Format A1:D1 as bold, vertical alignment = center.
      With shXL.Range("A1", "D1")
         .Font.Bold = True
         .VerticalAlignment = Excel.XlVAlign.xlVAlignCenter
      End With
      
      ' Create an array to set multiple values at once.
      Dim students(5, 2) As String
      students(0, 0) = "Zara"
      students(0, 1) = "Ali"
      students(1, 0) = "Nuha"
      students(1, 1) = "Ali"
      students(2, 0) = "Arilia"
      students(2, 1) = "RamKumar"
      students(3, 0) = "Rita"
      students(3, 1) = "Jones"
      students(4, 0) = "Umme"
      students(4, 1) = "Ayman"
      
      ' Fill A2:B6 with an array of values (First and Last Names).
      shXL.Range("A2", "B6").Value = students
      
      ' Fill C2:C6 with a relative formula (=A2 & " " & B2).
      raXL = shXL.Range("C2", "C6")
      raXL.Formula = "=A2 & "" "" & B2"
       
      ' Fill D2:D6 values.
      With shXL
         .Cells(2, 4).Value = "Biology"
         .Cells(3, 4).Value = "Mathmematics"
         .Cells(4, 4).Value = "Physics"
         .Cells(5, 4).Value = "Mathmematics"
         .Cells(6, 4).Value = "Arabic"
      End With
      
      ' AutoFit columns A:D.
      raXL = shXL.Range("A1", "D1")
      raXL.EntireColumn.AutoFit()
      
      ' Make sure Excel is visible and give the user control
      ' of Excel's lifetime.
      appXL.Visible = True
      appXL.UserControl = True
      
      ' Release object references.
      raXL = Nothing
      shXL = Nothing
      wbXl = Nothing
      appXL.Quit()
      appXL = Nothing
      Exit Sub
Err_Handler:
      MsgBox(Err.Description, vbCritical, "Error: " & Err.Number)
   End Sub
End Class

当使用 Microsoft Visual Studio 工具栏上的启动按钮执行和运行上述代码时，它将显示以下窗口：

单击按钮将显示以下 Excel 表格。系统将要求您保存工作簿。

VB.Net - 发送邮件

VB.Net 允许从您的应用程序发送电子邮件。System.Net.Mail 命名空间包含用于将电子邮件发送到简单邮件传输协议 (SMTP) 服务器以进行传递的类。

下表列出了一些常用类：

SmtpClient 类

SmtpClient 类允许应用程序使用简单邮件传输协议 (SMTP) 发送电子邮件。

以下是 SmtpClient 类的一些常用属性：

以下是 SmtpClient 类的一些常用方法：

以下示例演示如何使用 SmtpClient 类发送邮件。在这方面需要注意以下几点：

• 您必须指定用于发送电子邮件的 SMTP 主机服务器。不同主机服务器的Host和Port属性将有所不同。我们将使用 gmail 服务器。

• 如果 SMTP 服务器需要，您需要提供用于身份验证的Credentials。

• 您还应分别使用MailMessage.From和MailMessage.To属性提供发件人的电子邮件地址和收件人的电子邮件地址。

• 您还应使用MailMessage.Body属性指定消息内容。

示例

在此示例中，让我们创建一个简单的应用程序来发送电子邮件。请按照以下步骤操作：

• 在窗体中添加三个标签、三个文本框和一个按钮控件。

• 将标签的文本属性分别更改为“发件人”、“收件人：”和“消息：”。

• 将文本的名称属性分别更改为 txtFrom、txtTo 和 txtMessage。

• 将按钮控件的文本属性更改为“发送”。

• 在代码编辑器中添加以下代码。

Imports System.Net.Mail
Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspoint.com"
   End Sub

   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      Try
         Dim Smtp_Server As New SmtpClient
         Dim e_mail As New MailMessage()
         Smtp_Server.UseDefaultCredentials = False
         Smtp_Server.Credentials = New Net.NetworkCredential("[email protected]", "password")
         Smtp_Server.Port = 587
         Smtp_Server.EnableSsl = True
         Smtp_Server.Host = "smtp.gmail.com"

         e_mail = New MailMessage()
         e_mail.From = New MailAddress(txtFrom.Text)
         e_mail.To.Add(txtTo.Text)
         e_mail.Subject = "Email Sending"
         e_mail.IsBodyHtml = False
         e_mail.Body = txtMessage.Text
         Smtp_Server.Send(e_mail)
         MsgBox("Mail Sent")

      Catch error_t As Exception
         MsgBox(error_t.ToString)
      End Try
   End Sub

• 您必须提供您的 gmail 地址和真实密码作为凭据。

• 当使用 Microsoft Visual Studio 工具栏中的启动按钮执行并运行上述代码时，将显示以下窗口，您可以使用它来发送电子邮件，请自己尝试。

VB.Net - XML处理

可扩展标记语言 (XML) 是一种类似于 HTML 或 SGML 的标记语言。这是万维网联盟推荐的开放标准。

.Net Framework 中的System.Xml命名空间包含用于处理 XML 文档的类。以下是 System.Xml 命名空间中的一些常用类。

XML 解析器 API

用于 XML 数据的两个最基本且使用最广泛的 API 是 SAX 和 DOM 接口。

• 用于 XML 的简单 API (SAX) − 在这里，您为感兴趣的事件注册回调，然后让解析器遍历文档。当您的文档很大或内存有限时，这非常有用，它在从磁盘读取文件时解析文件，并且整个文件永远不会存储在内存中。

• 文档对象模型 (DOM) API − 这是万维网联盟的建议，其中整个文件被读取到内存中并存储在分层（基于树）的形式中，以表示 XML 文档的所有功能。

处理大型文件时，SAX 的处理速度显然不如 DOM 快。另一方面，仅使用 DOM 会严重消耗您的资源，尤其是在处理大量小文件时。

SAX 是只读的，而 DOM 允许更改 XML 文件。由于这两个不同的 API 实际上是互补的，因此没有理由不将它们都用于大型项目。

对于我们所有的 XML 代码示例，让我们使用一个简单的 XML 文件 movies.xml 作为输入 −

<?xml version = "1.0"?>

<collection shelf = "New Arrivals">
   <movie title = "Enemy Behind">
      <type>War, Thriller</type>
      <format>DVD</format>
      <year>2003</year>
      <rating>PG</rating>
      <stars>10</stars>
      <description>Talk about a US-Japan war</description>
   </movie>

   <movie title = "Transformers">
      <type>Anime, Science Fiction</type>
      <format>DVD</format>
      <year>1989</year>
      <rating>R</rating>
      <stars>8</stars>
      <description>A schientific fiction</description>
   </movie>

   <movie title = "Trigun">
      <type>Anime, Action</type>
      <format>DVD</format>
      <episodes>4</episodes>
      <rating>PG</rating>
      <stars>10</stars>
      <description>Vash the Stampede!</description>
   </movie>

   <movie title = "Ishtar">
      <type>Comedy</type>
      <format>VHS</format>
      <rating>PG</rating>
      <stars>2</stars>
      <description>Viewable boredom</description>
   </movie>
</collection>

使用 SAX API 解析 XML

在 SAX 模型中，您使用XmlReader 和XmlWriter 类来处理 XML 数据。

XmlReader 类用于以快速、仅向前和非缓存的方式读取 XML 数据。它读取 XML 文档或流。

示例 1

此示例演示如何从 movies.xml 文件读取 XML 数据。

请按照以下步骤操作：

• 将 movies.xml 文件添加到应用程序的 bin\Debug 文件夹中。

• 在 Form1.vb 文件中导入 System.Xml 命名空间。

• 在窗体中添加一个标签，并将它的文本更改为“Movies Galore”。

• 添加三个列表框和三个按钮，以显示来自 xml 文件的电影标题、类型和描述。

• 使用代码编辑器窗口添加以下代码。

Imports System.Xml
Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspoint.com"
   End Sub
   
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      ListBox1().Items.Clear()
      Dim xr As XmlReader = XmlReader.Create("movies.xml")
      Do While xr.Read()
         If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "movie" Then
            ListBox1.Items.Add(xr.GetAttribute(0))
         End If
      Loop
   End Sub
   
   Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
      ListBox2().Items.Clear()
      Dim xr As XmlReader = XmlReader.Create("movies.xml")
      Do While xr.Read()
         If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "type" Then
            ListBox2.Items.Add(xr.ReadElementString)
         Else
            xr.Read()
         End If
      Loop
   End Sub
   
   Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
      ListBox3().Items.Clear()
      Dim xr As XmlReader = XmlReader.Create("movies.xml")
      Do While xr.Read()
         If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "description" Then
            ListBox3.Items.Add(xr.ReadElementString)
         Else
            xr.Read()
         End If
      Loop
   End Sub
End Class

使用 Microsoft Visual Studio 工具栏上的启动按钮执行并运行上述代码。单击按钮将显示来自文件电影的标题、类型和描述。

XmlWriter 类用于将 XML 数据写入流、文件或 TextWriter 对象。它也以仅向前、非缓存的方式工作。

示例 2

让我们通过在运行时添加一些数据来创建一个 XML 文件。请按照以下步骤操作 −

• 在窗体中添加一个 WebBrowser 控件和一个按钮控件。

• 将按钮的 Text 属性更改为“显示作者文件”。

• 在代码编辑器中添加以下代码。

Imports System.Xml
Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspoint.com"
   End Sub
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      Dim xws As XmlWriterSettings = New XmlWriterSettings()
      xws.Indent = True
      xws.NewLineOnAttributes = True
      Dim xw As XmlWriter = XmlWriter.Create("authors.xml", xws)
      xw.WriteStartDocument()
      xw.WriteStartElement("Authors")
      xw.WriteStartElement("author")
      xw.WriteAttributeString("code", "1")
      xw.WriteElementString("fname", "Zara")
      xw.WriteElementString("lname", "Ali")
      xw.WriteEndElement()
      xw.WriteStartElement("author")
      xw.WriteAttributeString("code", "2")
      xw.WriteElementString("fname", "Priya")
      xw.WriteElementString("lname", "Sharma")
      xw.WriteEndElement()
      xw.WriteStartElement("author")
      xw.WriteAttributeString("code", "3")
      xw.WriteElementString("fname", "Anshuman")
      xw.WriteElementString("lname", "Mohan")
      xw.WriteEndElement()
      xw.WriteStartElement("author")
      xw.WriteAttributeString("code", "4")
      xw.WriteElementString("fname", "Bibhuti")
      xw.WriteElementString("lname", "Banerjee")
      xw.WriteEndElement()
      xw.WriteStartElement("author")
      xw.WriteAttributeString("code", "5")
      xw.WriteElementString("fname", "Riyan")
      xw.WriteElementString("lname", "Sengupta")
      xw.WriteEndElement()
      xw.WriteEndElement()
      xw.WriteEndDocument()
      xw.Flush()
      xw.Close()
      WebBrowser1.Url = New Uri(AppDomain.CurrentDomain.BaseDirectory + "authors.xml")
   End Sub
End Class

• 使用 Microsoft Visual Studio 工具栏上的启动按钮执行并运行上述代码。单击“显示作者文件”将显示在 Web 浏览器上新创建的 authors.xml 文件。

使用 DOM API 解析 XML

根据文档对象模型 (DOM)，XML 文档由节点和节点的属性组成。XmlDocument 类用于实现 .Net Framework 的 XML DOM 解析器。它还允许您通过插入、删除或更新文档中的数据来修改现有的 XML 文档。

以下是XmlDocument 类的一些常用方法 −

示例 3

在此示例中，让我们在 xml 文档 authors.xml 中插入一些新节点，然后在列表框中显示所有作者的姓名。

请按照以下步骤操作：

• 将 authors.xml 文件添加到应用程序的 bin/Debug 文件夹中（如果您尝试过上一个示例，则应该存在）。

• 导入 System.Xml 命名空间

• 在窗体中添加一个列表框和一个按钮控件，并将按钮控件的 Text 属性设置为“显示作者”。

• 使用代码编辑器添加以下代码。

Imports System.Xml
Public Class Form1
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
      ' Set the caption bar text of the form.   
      Me.Text = "tutorialspoint.com"
   End Sub
   
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
      ListBox1.Items.Clear()
      
      Dim xd As XmlDocument = New XmlDocument()
      xd.Load("authors.xml")
      
      Dim newAuthor As XmlElement = xd.CreateElement("author")
      newAuthor.SetAttribute("code", "6")
      
      Dim fn As XmlElement = xd.CreateElement("fname")
      fn.InnerText = "Bikram"
      newAuthor.AppendChild(fn)
      
      Dim ln As XmlElement = xd.CreateElement("lname")
      ln.InnerText = "Seth"
      newAuthor.AppendChild(ln)
      xd.DocumentElement.AppendChild(newAuthor)
      
      Dim tr As XmlTextWriter = New XmlTextWriter("movies.xml", Nothing)
      tr.Formatting = Formatting.Indented
      xd.WriteContentTo(tr)
      tr.Close()
      
      Dim nl As XmlNodeList = xd.GetElementsByTagName("fname")
      
      For Each node As XmlNode In nl
         ListBox1.Items.Add(node.InnerText)
      Next node
   End Sub
End Class

• 使用 Microsoft Visual Studio 工具栏上的启动按钮执行并运行上述代码。单击“显示作者”按钮将显示所有作者的姓名，包括我们在运行时添加的姓名。

VB.Net - Web编程

动态 Web 应用程序包含以下两种类型的程序之一或两者 −

• 服务器端脚本 − 这些是在 Web 服务器上执行的程序，使用服务器端脚本语言（如 ASP（Active Server Pages）或 JSP（Java Server Pages））编写。

• 客户端脚本 − 这些是在浏览器上执行的程序，使用脚本语言（如 JavaScript、VBScript 等）编写。

ASP.Net 是微软推出的 ASP 的 .Net 版本，用于通过使用服务器端脚本创建动态网页。ASP.Net 应用程序是使用 .Net Framework 中存在的可扩展和可重用组件或对象编写的已编译代码。这些代码可以使用 .Net Framework 中的整个类层次结构。

ASP.Net 应用程序代码可以用以下任何一种语言编写 −

• Visual Basic .Net

• C#

• Jscript

• J#

在本节中，我们将简要介绍如何使用 VB.Net 编写 ASP.Net 应用程序。有关详细讨论，请参阅ASP.Net 教程。

ASP.Net 内置对象

ASP.Net 有一些在 Web 服务器上运行的内置对象。这些对象具有在应用程序开发中使用的属性、方法和集合。

下表列出了 ASP.Net 内置对象及其简要说明 −

ASP.Net编程模型

ASP.Net 提供两种编程模型：

• Web 窗体 - 这使您可以创建用户界面和应用于用户界面各个组件的应用程序逻辑。

• WCF 服务 - 这使您可以远程访问某些服务器端功能。

在本节中，您需要使用 Visual Studio Web Developer，它是免费的。此 IDE 与您之前用于创建 Windows 应用程序的 IDE 几乎相同。

Web 窗体

Web 窗体包含：

• 用户界面

• 应用程序逻辑

用户界面由静态 HTML 或 XML 元素和 ASP.Net 服务器控件组成。创建 Web 应用程序时，HTML 或 XML 元素和服务器控件存储在扩展名为.aspx的文件中。此文件也称为页面文件。

应用程序逻辑包含应用于页面中用户界面元素的代码。您可以使用任何 .Net 语言（如 VB.Net 或 C#）编写此代码。下图显示了设计视图中的 Web 窗体：

示例

让我们创建一个包含 Web 窗体的新网站，该窗体将在用户单击按钮时显示当前日期和时间。请按照以下步骤操作：

• 选择 文件 → 新建 → 网站。将出现“新建网站”对话框。

• 选择 ASP.Net 空网站模板。键入网站名称并选择保存文件的路径。

• 您需要向网站添加一个默认页面。右键单击解决方案资源管理器中的网站名称，然后从上下文菜单中选择“添加新项”选项。将显示“添加新项”对话框：

• 选择 Web 窗体选项，并为默认页面提供名称。我们将其命名为 Default.aspx。单击“添加”按钮。

• 默认页面在源视图中显示。

• 通过在源视图中向页面的<Title>标记添加值来设置默认 Web 页面的标题：

• 若要在 Web 页面上添加控件，请转到设计视图。在窗体上添加三个标签、一个文本框和一个按钮。

• 双击该按钮，并将以下代码添加到该按钮的 Click 事件中：

Protected Sub Button1_Click(sender As Object, e As EventArgs) _
Handles Button1.Click
   Label2.Visible = True
   Label2.Text = "Welcome to Tutorials Point: " + TextBox1.Text
   Label3.Text = "You visited us at: " + DateTime.Now.ToString()
End Sub

使用 Microsoft Visual Studio 工具栏上的“启动”按钮执行并运行上述代码后，浏览器中将打开以下页面：

输入您的姓名，然后单击“提交”按钮：

Web 服务

Web 服务是一个 Web 应用程序，它基本上是一个类，包含可供其他应用程序使用的方法。它也遵循类似于 ASP.Net 网页的代码隐藏架构，尽管它没有用户界面。

.Net Framework 的早期版本使用了这种 ASP.Net Web 服务的概念，其文件扩展名为 .asmx。但是，从 .Net Framework 4.0 开始，Windows Communication Foundation (WCF) 技术已发展成为 Web 服务、.Net Remoting 和其他一些相关技术的新的继承者。它实际上将所有这些技术整合在一起。在下一节中，我们将简要介绍 Windows Communication Foundation (WCF)。

如果您使用的是早期版本的 .Net Framework，您仍然可以创建传统的 Web 服务。请参阅ASP.Net - Web 服务教程以获取详细说明。

Windows Communication Foundation

Windows Communication Foundation 或 WCF 提供了一个 API，用于创建称为 WCF 服务的分布式面向服务的应用程序。

与 Web 服务一样，WCF 服务也支持应用程序之间的通信。但是，与 Web 服务不同的是，这里的通信并不仅限于 HTTP。WCF 可以配置为通过 HTTP、TCP、IPC 和消息队列使用。WCF 的另一个优点是，它支持双工通信，而 Web 服务只能实现单工通信。

从初学者的角度来看，编写 WCF 服务与编写 Web 服务并没有什么不同。为了简化操作，我们将了解如何：

• 创建 WCF 服务

• 创建服务契约并定义操作

• 实现契约

• 测试服务

• 利用服务

示例

为了理解这个概念，让我们创建一个简单的服务，它将提供股票价格信息。客户端可以根据股票代码查询股票的名称和价格。为了简化此示例，值硬编码在一个二维数组中。此服务将具有两种方法：

• GetPrice 方法 - 它将根据提供的代码返回股票的价格。

• GetName 方法 - 它将根据提供的代码返回股票的名称。

创建 WCF 服务

请按照以下步骤操作：

• 打开 VS Express for Web 2012

• 选择“新建网站”以打开“新建网站”对话框。

• 从模板列表中选择 WCF 服务模板：

• 从“Web 位置”下拉列表中选择“文件系统”。

• 为 WCF 服务提供名称和位置，然后单击“确定”。

• 将创建一个新的 WCF 服务。

创建服务契约并定义操作

服务契约定义服务执行的操作。在 WCF 服务应用程序中，您会发现解决方案资源管理器中的 App_Code 文件夹中自动创建了两个文件。

• IService.vb - 这将包含服务契约；简单来说，它将包含服务的接口，其中包含服务将提供的方法的定义，您将在服务中实现这些方法。

• Service.vb - 这将实现服务契约。

• 将 IService.vb 文件的代码替换为给定的代码：

Public Interface IService
   <OperationContract()>
   Function GetPrice(ByVal symbol As String) As Double

   <OperationContract()>
   Function GetName(ByVal symbol As String) As String
End Interface

实现契约

在 Service.vb 文件中，您会找到一个名为Service的类，它将实现IService接口中定义的服务契约。

将 IService.vb 的代码替换为以下代码：

' NOTE: You can use the "Rename" command on the context menu to change the class name "Service" in code, svc and config file together.
Public Class Service
   Implements IService
   Public Sub New()
   End Sub
   Dim stocks As String(,) =
   {
      {"RELIND", "Reliance Industries", "1060.15"},
      {"ICICI", "ICICI Bank", "911.55"},
      {"JSW", "JSW Steel", "1201.25"},
      {"WIPRO", "Wipro Limited", "1194.65"},
      {"SATYAM", "Satyam Computers", "91.10"}
   }

   Public Function GetPrice(ByVal symbol As String) As Double _
   Implements IService.GetPrice

      Dim i As Integer
      'it takes the symbol as parameter and returns price
      For i = 0 To i = stocks.GetLength(0) - 1

         If (String.Compare(symbol, stocks(i, 0)) = 0) Then
            Return Convert.ToDouble(stocks(i, 2))
         End If
      Next i
      Return 0
   End Function

   Public Function GetName(ByVal symbol As String) As String _
   Implements IService.GetName

      ' It takes the symbol as parameter and 
      ' returns name of the stock
      Dim i As Integer
      For i = 0 To i = stocks.GetLength(0) - 1

         If (String.Compare(symbol, stocks(i, 0)) = 0) Then
            Return stocks(i, 1)
         End If
      Next i
      Return "Stock Not Found"
   End Function
End Class

测试服务

要运行创建的 WCF 服务，请选择菜单栏中的调试 → 启动调试选项。输出将是：

要测试服务操作，请双击左侧窗格中操作的名称。右侧窗格中将出现一个新选项卡。

在右侧窗格的“请求”区域中输入参数值，然后单击“调用”按钮。

下图显示了测试GetPrice操作的结果：

下图显示了测试GetName操作的结果：

利用服务

让我们在同一个解决方案中添加一个默认页面（一个 ASP.NET Web 窗体），我们将从中使用刚刚创建的 WCF 服务。

请按照以下步骤操作：

• 右键单击解决方案资源管理器中的解决方案名称，然后向解决方案添加新的 Web 窗体。它将被命名为 Default.aspx。

• 在窗体上添加两个标签、一个文本框和一个按钮。

• 我们需要向刚刚创建的 WCF 服务添加服务引用。右键单击解决方案资源管理器中的网站，然后选择“添加服务引用”选项。这将打开“添加服务引用”对话框。

• 在“地址”文本框中输入服务的 URL（位置），然后单击“转到”按钮。它将创建一个默认名称为ServiceReference1的服务引用。单击“确定”按钮。

添加引用将为您的项目完成两项工作：

• 在 web.config 文件中创建服务的地址和绑定。

• 创建一个代理类来访问服务。

• 双击窗体中的“获取价格”按钮，在其 Click 事件中输入以下代码片段：

Partial Class _Default
   Inherits System.Web.UI.Page

   Protected Sub Button1_Click(sender As Object, e As EventArgs) _
   Handles Button1.Click
      Dim ser As ServiceReference1.ServiceClient = _ 
      New ServiceReference1.ServiceClient
      Label2.Text = ser.GetPrice(TextBox1.Text).ToString()
   End Sub
End Class

• 使用 Microsoft Visual Studio 工具栏上的“启动”按钮执行并运行上述代码后，浏览器中将打开以下页面：

• 输入一个代码，然后单击“获取价格”按钮以获取硬编码的价格：