Arduino - 字符串

上一页
下一页

字符串用于存储文本。它们可以用于在 LCD 或 Arduino IDE 串口监视器窗口中显示文本。字符串也可用于存储用户输入。例如，用户在连接到 Arduino 的键盘上输入的字符。

Arduino 编程中有两种类型的字符串：

  • 字符数组，与 C 编程中使用的字符串相同。
  • Arduino String，它允许我们在草图中使用字符串对象。

在本章中，我们将学习字符串、对象以及字符串在 Arduino 草图中的使用。在本章结束时，您将学习在草图中使用哪种类型的字符串。

字符串字符数组

我们将学习的第一种字符串类型是字符序列，其类型为char。在上一章中，我们学习了什么是数组；存储在内存中的相同类型变量的连续序列。字符串是 char 变量的数组。

字符串是一个特殊的数组，在其末尾有一个额外的元素，该元素始终值为 0（零）。这称为“以 null 结尾的字符串”。

字符串字符数组示例

此示例将演示如何创建字符串并将其打印到串口监视器窗口。

示例

void setup() {
   char my_str[6]; // an array big enough for a 5 character string
   Serial.begin(9600);
   my_str[0] = 'H'; // the string consists of 5 characters
   my_str[1] = 'e';
   my_str[2] = 'l';
   my_str[3] = 'l';
   my_str[4] = 'o';
   my_str[5] = 0; // 6th array element is a null terminator
   Serial.println(my_str);
}

void loop() { 

}

以下示例显示了字符串的构成；一个包含可打印字符的字符数组，以及数组的最后一个元素为 0，以表示字符串在此处结束。可以通过使用Serial.println()并传递字符串的名称来将字符串打印到 Arduino IDE 串口监视器窗口。

此相同的示例可以用更方便的方式编写，如下所示：

示例

void setup() {
   char my_str[] = "Hello";
   Serial.begin(9600);
   Serial.println(my_str);
}

void loop() {

}

在此草图中，编译器计算字符串数组的大小，并自动以零结束字符串。创建了一个长度为六个元素的数组，该数组包含五个字符，后跟一个零，这与上一个草图中的创建方式完全相同。

操作字符串数组

我们可以在草图中更改字符串数组，如下面的草图所示。

示例

void setup() {
   char like[] = "I like coffee and cake"; // create a string
   Serial.begin(9600);
   // (1) print the string
   Serial.println(like);
   // (2) delete part of the string
   like[13] = 0;
   Serial.println(like);
   // (3) substitute a word into the string
   like[13] = ' '; // replace the null terminator with a space
   like[18] = 't'; // insert the new word
   like[19] = 'e';
   like[20] = 'a';
   like[21] = 0; // terminate the string
   Serial.println(like);
}

void loop() {

}

结果

I like coffee and cake
I like coffee
I like coffee and tea

草图的工作原理如下。

创建和打印字符串

在上面给出的草图中，创建了一个新的字符串，然后打印出来以在串口监视器窗口中显示。

缩短字符串

通过将字符串中的第 14 个字符替换为 null 终止符零 (2) 来缩短字符串。这是从 0 开始计数的字符串数组中的第 13 个元素。

打印字符串时，将打印所有字符直至新的 null 终止符。其他字符不会消失；它们仍然存在于内存中，并且字符串数组的大小仍然相同。唯一的区别是，任何处理字符串的函数都只会看到字符串直至第一个 null 终止符。

更改字符串中的一个单词

最后，草图将单词“cake”替换为“tea”（3）。它首先必须将 like[13] 处的 null 终止符替换为空格，以便将字符串恢复为最初创建的格式。

新字符用单词“tea”覆盖单词“cake”的“cak”。这是通过覆盖单个字符来完成的。“cake”的“e”被替换为一个新的 null 终止符。结果是字符串实际上以两个 null 字符结束，一个是字符串末尾的原始 null 字符，另一个是替换“cake”中“e”的新 null 字符。当打印新字符串时，这没有什么区别，因为打印字符串的函数在遇到第一个 null 终止符时停止打印字符串字符。

操作字符串数组的函数

前面的草图通过访问字符串中的单个字符以手动方式操作字符串。为了更轻松地操作字符串数组，您可以编写自己的函数来执行此操作，或者使用C语言库中的一些字符串函数。

下一个草图使用了一些 C 字符串函数。

示例

void setup() {
   char str[] = "This is my string"; // create a string
   char out_str[40]; // output from string functions placed here
   int num; // general purpose integer
   Serial.begin(9600);

   // (1) print the string
   Serial.println(str);

   // (2) get the length of the string (excludes null terminator)
   num = strlen(str);
   Serial.print("String length is: ");
   Serial.println(num);

   // (3) get the length of the array (includes null terminator)
   num = sizeof(str); // sizeof() is not a C string function
   Serial.print("Size of the array: ");
   Serial.println(num);

   // (4) copy a string
   strcpy(out_str, str);
   Serial.println(out_str);

   // (5) add a string to the end of a string (append)
   strcat(out_str, " sketch.");
   Serial.println(out_str);
   num = strlen(out_str);
   Serial.print("String length is: ");
   Serial.println(num);
   num = sizeof(out_str);
   Serial.print("Size of the array out_str[]: ");
   Serial.println(num);
}

void loop() {

}

结果

This is my string
String length is: 17
Size of the array: 18
This is my string
This is my string sketch.
String length is: 25
Size of the array out_str[]: 40

草图的工作原理如下。

打印字符串

新创建的字符串被打印到串口监视器窗口，就像在以前的草图中一样。

获取字符串的长度

strlen() 函数用于获取字符串的长度。字符串的长度仅针对可打印字符，不包括 null 终止符。

字符串包含 17 个字符，因此我们在串口监视器窗口中看到打印的 17。

获取数组的长度

操作符 sizeof() 用于获取包含字符串的数组的长度。长度包括空终止符，因此长度比字符串长度多一。

sizeof() 看起来像一个函数，但从技术上讲是一个操作符。它不是 C 字符串库的一部分，但在草图中使用它来显示数组大小和字符串大小（或字符串长度）之间的区别。

复制字符串

strcpy() 函数用于将 str[] 字符串复制到 out_num[] 数组。strcpy() 函数将传递给它的第二个字符串复制到第一个字符串中。现在 out_num[] 数组中存在字符串的副本，但它只占用数组的 18 个元素，因此我们仍然在数组中拥有 22 个空闲的 char 元素。这些空闲元素位于内存中字符串之后。

字符串被复制到数组中，以便我们在数组中有一些额外的空间可以在草图的下一部分使用，即在字符串末尾添加字符串。

将字符串附加到字符串（连接）

草图将一个字符串连接到另一个字符串，这被称为连接。这是使用 strcat() 函数完成的。strcat() 函数将传递给它的第二个字符串放在传递给它的第一个字符串的末尾。

连接后，打印字符串长度以显示新的字符串长度。然后打印数组长度以显示我们在 40 个元素的数组中有一个 25 个字符长的字符串。

请记住，由于空终止零，25 个字符长的字符串实际上占用了数组的 26 个字符。

数组边界

在处理字符串和数组时，务必在字符串或数组的范围内操作。在示例草图中，创建了一个 40 个字符长的数组，以便分配可用于操作字符串的内存。

如果数组设置得太小，并且我们尝试将一个比数组更大的字符串复制到其中，则该字符串将被复制到数组的末尾之外。数组末尾之外的内存可能包含草图中使用的其他重要数据，这些数据将被我们的字符串覆盖。如果字符串末尾之外的内存被越界，则可能导致草图崩溃或出现意外行为。

打印页面
上一页
下一页
广告